Usando AutoComplete em Textboxs de VFP 9

[Marcos Guedes]

Segue um ótimo código com exemplo de auto complete com VFP 9:

Código:

PUBLIC ofrm

ofrm=NEWOBJECT("frm_autocompletar")
ofrm.SHOW
RETURN

DEFINE CLASS frm_autocompletar AS FORM

   AUTOSIZE = .T.
   HEIGHT = 236
   WIDTH = 447
   DOCREATE = .T.
   CAPTION = "Usando Autocompletar"
   MAXBUTTON = .F.
   MINBUTTON = .F.
   NAME = "frm_autoCompletar"

   ADD OBJECT txt1 AS txt WITH ;
      TOP = 30, ;
      AUTOCOMPLETE = 1, ;
      AUTOCOMPSOURCE = "txtDemo"

   ADD OBJECT txt2 AS txt WITH ;
      TOP = 80, ;
      AUTOCOMPLETE = 2, ;
      AUTOCOMPSOURCE = "txtDemo"

   ADD OBJECT txt3 AS txt WITH ;
      TOP = 133, ;
      AUTOCOMPLETE = 3, ;
      AUTOCOMPSOURCE = "txtDemo"

   ADD OBJECT txt4 AS txt WITH ;
      LEFT = 23, ;
      TOP = 192, ;
      WIDTH = 169, ;
      AUTOCOMPLETE = 4

   ADD OBJECT txt5 AS txt WITH ;
      LEFT = 203, ;
      TOP = 190, ;
      WIDTH = 169, ;
      AUTOCOMPLETE = 4

   ADD OBJECT lbl4 AS lbl WITH ;
      CAPTION = "Ordenamiento Por codigo (AutoComplete = 4)", ;
      TOP = 170

   ADD OBJECT lbl3 AS lbl WITH ;
      CAPTION = "Ordenamiento Por ultima vez usado (AutoComplete = 3)", ;
      TOP = 114

   ADD OBJECT lbl2 AS lbl WITH ;
      CAPTION = "Ordenamiento Por mas usado (AutoComplete = 2)", ;
      TOP = 61

   ADD OBJECT lbl1 AS lbl WITH ;
      CAPTION = "Ordenamiento Alfabetico (AutoComplete = 1)", ;
      TOP = 10

   PROCEDURE txt4.VALID
      IF DODEFAULT()
         UPDATE (THIS.AUTOCOMPTABLE) SET weight = 1 WHERE ALLTRIM(UPPER(SOURCE)) = ;
            IIF(EMPTY(THIS.AUTOCOMPSOURCE),ALLTRIM(UPPER(THIS.NAME)),ALLTRIM(UPPER(THIS.AUTOCOMPSOURCE)))

         UPDATE (THIS.AUTOCOMPTABLE) SET weight = 0 WHERE ALLTRIM(UPPER(DATA)) = ;
            ALLTRIM(UPPER(THIS.VALUE)) AND ALLTRIM(UPPER(SOURCE)) = ;
            IIF(EMPTY(THIS.AUTOCOMPSOURCE),ALLTRIM(UPPER(THIS.NAME)),ALLTRIM(UPPER(THIS.AUTOCOMPSOURCE)))

         USE IN (THIS.AUTOCOMPTABLE)
      ENDIF
   ENDPROC

   PROCEDURE txt5.VALID
      IF DODEFAULT()
         UPDATE (THIS.AUTOCOMPTABLE) SET weight = 0 WHERE ALLTRIM(UPPER(SOURCE)) = ;
            IIF(EMPTY(THIS.AUTOCOMPSOURCE),ALLTRIM(UPPER(THIS.NAME)),ALLTRIM(UPPER(THIS.AUTOCOMPSOURCE)))

         UPDATE (THIS.AUTOCOMPTABLE) SET weight = 1 WHERE ALLTRIM(UPPER(DATA)) = ;
            ALLTRIM(UPPER(THIS.VALUE)) AND ALLTRIM(UPPER(SOURCE)) = ;
            IIF(EMPTY(THIS.AUTOCOMPSOURCE),ALLTRIM(UPPER(THIS.NAME)),ALLTRIM(UPPER(THIS.AUTOCOMPSOURCE)))

         USE IN (THIS.AUTOCOMPTABLE)
      ENDIF
   ENDPROC

ENDDEFINE

DEFINE CLASS lbl AS LABEL

   AUTOSIZE = .T.
   BACKSTYLE = 0
   LEFT = 24

ENDDEFINE



DEFINE CLASS txt AS TEXTBOX

   HEIGHT = 25
   LEFT = 24
   WIDTH = 265
   AUTOCOMPTABLE = "AutoCompletar"

ENDDEFINE

Fonte:
[Você precisa estar registrado e conectado para ver este link.]

[hugo]

fino patrao

[alceu11]

Tenho duvida mais nao leva mal!!!
Para que serve o auto complemento no fox,,,,,, estou digitando no text box o nome da empresa,,,,,,,Lobril comercio ,,,,,,,o que acontece com auto complemento?

[Marcos Guedes]

Imagine um preenchimento de um formulário de cadastro onde, ao invés de o usuário sempre re-escrever as informações, apenas escolha a opção desejada conforme o que já está armazenado numa tabela.

É como ocorre no Google enquanto digitamos algo para pesquisa.

[marcio]

Muito bom. Vamos utilizar a ferramenta.

[Marcos Guedes]

conheço este tipo de funcionalidade, embora faz muito tempo que não vejo mais aplicações que se comportam desta forma.

a desvantagem nisto é porque, se não me falha a memória, o campo textbox está vinculado diretamente a um campo de uma tabela DBF.

Este auto complete apresentado na primeira mensagem deste tópico, é uma alternativa que pode ser utilizada desde dados de um cursor, ou variáveis, por exemplo.

Então imagine um sistema onde você cria uma collection e vai adicionando informações, e... enquanto o módulo estiver aberto, o usuário poderá recuperar estes dados sem precisar re-digitá-lo, depois de fechado, então os dados não precisam ser mais utilizados, ou seja, nem precisei utilizar tabelas.

[hugo]

um assunto meio que "parecido", uma mesclagem de sugestao/autocomplete

[Você precisa estar registrado e conectado para ver este link.]