Google Maps

[Marcos Guedes]

Relembrando a primeira mensagem :

Realize suas consultas por localidades utilizando o recursos do [Você precisa estar registrado e conectado para ver este link.]:

Como utilizar:

Código:

CLEAR

LOCAL nomecursor AS STRING
m.nomecursor = m.googleMaps("Morro do Careca")

IF USED(m.nomecursor) THEN
   SELECT(m.nomecursor)
   GO TOP
   BROWSE
   USE IN SELECT(m.nomecursor)
ENDIF

A função:

Código:

FUNCTION googleMaps AS STRING
   *!* Autor: Marcos Guedes
   *!* Fonte: http://forum.programacaobrasil.com/visual-foxpro-f4/google-maps-t384.htm
   LPARAMETERS localidade AS STRING, nomecursor AS STRING
   *!*
   LOCAL url AS STRING
   LOCAL parametros AS STRING
   LOCAL loxmlhttp AS OBJECT
   LOCAL strtemp2 AS STRING
   LOCAL cnome AS STRING
   LOCAL endereco AS STRING
   LOCAL cep AS STRING
   LOCAL ddd AS STRING
   LOCAL telefone AS STRING
   LOCAL conttemp AS INTEGER
   *!*
   IF (VARTYPE(m.localidade)!="C") THEN
      m.localidade = ""
   ENDIF
   IF (VARTYPE(m.nomecursor)!="C") OR EMPTY(m.nomecursor) THEN
      m.nomecursor = SYS(2015)
   ENDIF
   *!*
   m.url = "http://maps.google.com.br/maps?f=q&source=s_q&output=js&hl=pt-BR&geocode=&q=" + m.localidade + "&btnG=Pesquisar+no+Mapa&vps=1&jsv=182b&sll=-14.179186%2C-50.449219&sspn=33.483081%2C131.660156&abauth=fa677140%3AOYVhMvJnYkyS63VFfp1D9geCJUo&absince=21"
   m.parametros = ""
   *!*
   m.loxmlhttp = CREATEOBJECT("MSXML2.XMLHTTP")
   *!* Consulta a localidade a partir do site do Google Maps (http://maps.google.com/maps)
   m.loxmlhttp.OPEN("POST",m.url,.F.)
   m.loxmlhttp.setrequestheader("content-type", "application/x-www-form-urlencoded")
   m.loxmlhttp.SEND(m.parametros)
   m.lcresponse = loxmlhttp.responsetext
   m.loxmlhttp = .NULL.
   *!* Cursor que guardará as informações encontradas
   CREATE CURSOR (m.nomecursor) (cnome c(50), endereco c(100), cep c(20), ddd c(2), telefone c(10))
   *!*
   m.conttemp = 1
   m.cnome = STREXTRACT(m.lcresponse, [,name:"],[",],m.conttemp)
   DO WHILE !EMPTY(m.cnome)
      *!* Endereço completo
      m.strtemp2 = ALLTRIM(STRTRAN(STREXTRACT(m.lcresponse, [addressLines:["],'"],',m.conttemp),["], ""))
      *!* Extrai o CEP do endereço completo
      m.cep = STRTRAN( GETWORDNUM(m.strtemp2,GETWORDCOUNT(m.strtemp2,","),",") ,"-", "")
      *!* Extrai o endereço, sem o CEP
      m.endereco = ALLTRIM(STRTRAN( LEFT(m.strtemp2, LEN(m.strtemp2)-LEN(m.cep)) , ",", "", ;
         IIF(OCCURS(",",m.strtemp2)<=0,1,OCCURS(",",m.strtemp2))))
      *!* Telefone completo      
      m.strtemp2 = STREXTRACT(m.lcresponse, [phones:[{number:"(0xx)],'"}],',m.conttemp)      
      *!* Extrai o DDD do telefone completo
      ddd = GETWORDNUM(m.strtemp2, 1)
      *!* Extrai o telefone, sem o DDD
      m.telefone = GETWORDNUM(m.strtemp2, 2)
      *!* Insere os dados no cursor
      INSERT INTO (m.nomecursor) (cnome, endereco, cep, ddd, telefone) ;
         VALUES (m.cnome, m.endereco, ALLTRIM(m.cep), m.ddd, m.telefone)
      *!*
      m.conttemp = m.conttemp + 1
      *!* Próximo local encontrado
      m.cnome = STREXTRACT(m.lcresponse, [,name:"],[",],m.conttemp)
   ENDDO
   *!* Retorna o nome do cursor contendo as possíveis informações
   RETURN m.nomecursor
ENDFUNC

Espero que seja útil aos colegas!


Nota: Havendo alguma falha, ou algo que possa ser melhorado, favor comunicar!

[alceu11]

PRECISA aumentar o web browser para ver o mapa no formulario
com fazer isto ?

[Marcos Guedes]

Como assim aumentar?
Como está o teu?
Podes mandar um Print Screen da tela?

[alceu11]

pode fazer um form em vfp90 da pesquisa do mapa?

[Marcos Guedes]

Segue um projeto com 3 modelos.
Espero que ajude!

[Você precisa estar registrado e conectado para ver este link.]

[Marcos Guedes]

Consegui rodá-lo na versão 6 (em espanhol), também!
Segue o projeto completo:

[Você precisa estar registrado e conectado para ver este link.]

[alceu11]

Marcos agora que ta tudo funcionando preciso de mais uma funcionalidade,

[Você precisa estar registrado e conectado para ver este link.]
Preciso agora de como chegar, ele acha rua e posiciona no mapa,

Acima do link tem um tipo link ou botao como chegar
preciso que ele abra como chegar
para pegar o endereco de partida do prestador de servicos, para montar, qtos kms vai percorrer, e o tempo estimado, isto tudo o google faz,
So preciso que voce abra nesta rotina como chegar?
E possivel fazer isto Marcos?
[Você precisa estar registrado e conectado para ver este link.]
FICARIA ASSIM COMO CHEGAR CONF. LINK ACIMA

[Marcos Guedes]

Alceu, verei as possibilidades de extrair as informações que você precisa!

Caso não seja possível, no momento, acredito que em breve será utilizando a API do NAVTEQ:
- [Você precisa estar registrado e conectado para ver este link.]

[Marcos Guedes]

Alceu... ainda não tive tempo de fazer a rotina da forma como solicitasse.
Mas pesquisando na net, acredito que a API do Google é a mais indicada:

- [Você precisa estar registrado e conectado para ver este link.]
- [Você precisa estar registrado e conectado para ver este link.]

[hugo]

to de bobs roxo

caraca

colocar no sistema um botao pra galera da logistica
onde na montagem de carga o cara clica sobre o pedido
e ve na tela o mapa de onde ta o camarada, com km e tudo
mais

sinceramente, isto num sistema ficaria muito fino

bora jogar esta ideia la pro projeto (no futuro, claro)

hauahauahauahauaha

amo muito tudo isto!

[Marcos Guedes]

Estou devendo isto para o Alceu faz um tempo.

A forma provisória está numa mensagem que postei neste tópico:
[Você precisa estar registrado e conectado para ver este link.]

Porém, da forma como o Alceu pretende é melhor e mais elegante.

Só me resta tempo para estudar a API do Google e ver uma forma de montar este mapa numa aplicação desktop.

[hugo]

Voces estao de parabens!

[Marcos Guedes]

Marcos agora que ta tudo funcionando preciso de mais uma funcionalidade,

[Você precisa estar registrado e conectado para ver este link.]
Preciso agora de como chegar, ele acha rua e posiciona no mapa,

Acima do link tem um tipo link ou botao como chegar
preciso que ele abra como chegar
para pegar o endereco de partida do prestador de servicos, para montar, qtos kms vai percorrer, e o tempo estimado, isto tudo o google faz,
So preciso que voce abra nesta rotina como chegar?
E possivel fazer isto Marcos?
[Você precisa estar registrado e conectado para ver este link.]
FICARIA ASSIM COMO CHEGAR CONF. LINK ACIMA

Alceu, veja se é, mais ou menos isto que precisas:
[Você precisa estar registrado e conectado para ver este link.]

Obs.: Ainda têm algumas falhas que estou vendo como corrigir. Estou estudando a api, ainda.


Aguardo respostas.

[alceu11]

Marcos obrigado ficou muito legal.

Marcos mais nao vi como colocar o local de destino,
A origem vc ja tem , so falta o destisno
Origem e destino para fazer a rota, de como chegar

O objetivo, e qto tempo o prestador de servicos vai levar para sair da origem e chegar no destino e tracar o caminho que ira tomar para chegar ao destino?

Eu acho que estou pedindo demais me desculpe, se me espresse mal, ou nao tinha feito entedido direito anteriormente!!!
mais valeu ai hein

[Marcos Guedes]

Assim que possível verei isto também, Alceu.
Só não garanto que será logo.


Estou com o tempo curto e ainda estudando como utilizar, da melhor forma, a API do google.

[Tales Ruan]

Semana que vem vou começar a desenvolver um sistema para transportes e esse código vai ser extremamente útil!

Valeu Marcos!