Google Maps - <<<

[Marcos Guedes]

Realize suas consultas por localidades utilizando o recursos do Google Maps:

Como utilizar:

Código:

CLEAR

LOCAL nomecursor AS STRING
m.nomecursor = m.googleMaps("Morro do Careca")

IF USED(m.nomecursor) THEN
   SELECT(m.nomecursor)
   GO TOP
   BROWSE
   USE IN SELECT(m.nomecursor)
ENDIF

A função:

Código:

FUNCTION googleMaps AS STRING
   *!* Autor: Marcos Guedes
   *!* Fonte: http://forum.programacaobrasil.com/visual-foxpro-f4/google-maps-t384.htm
   LPARAMETERS localidade AS STRING, nomecursor AS STRING
   *!*
   LOCAL url AS STRING
   LOCAL parametros AS STRING
   LOCAL loxmlhttp AS OBJECT
   LOCAL strtemp2 AS STRING
   LOCAL cnome AS STRING
   LOCAL endereco AS STRING
   LOCAL cep AS STRING
   LOCAL ddd AS STRING
   LOCAL telefone AS STRING
   LOCAL conttemp AS INTEGER
   *!*
   IF (VARTYPE(m.localidade)!="C") THEN
      m.localidade = ""
   ENDIF
   IF (VARTYPE(m.nomecursor)!="C") OR EMPTY(m.nomecursor) THEN
      m.nomecursor = SYS(2015)
   ENDIF
   *!*
   m.url = "http://maps.google.com.br/maps?f=q&source=s_q&output=js&hl=pt-BR&geocode=&q=" + m.localidade + "&btnG=Pesquisar+no+Mapa&vps=1&jsv=182b&sll=-14.179186%2C-50.449219&sspn=33.483081%2C131.660156&abauth=fa677140%3AOYVhMvJnYkyS63VFfp1D9geCJUo&absince=21"
   m.parametros = ""
   *!*
   m.loxmlhttp = CREATEOBJECT("MSXML2.XMLHTTP")
   *!* Consulta a localidade a partir do site do Google Maps (http://maps.google.com/maps)
   m.loxmlhttp.OPEN("POST",m.url,.F.)
   m.loxmlhttp.setrequestheader("content-type", "application/x-www-form-urlencoded")
   m.loxmlhttp.SEND(m.parametros)
   m.lcresponse = loxmlhttp.responsetext
   m.loxmlhttp = .NULL.
   *!* Cursor que guardará as informações encontradas
   CREATE CURSOR (m.nomecursor) (cnome c(50), endereco c(100), cep c(20), ddd c(2), telefone c(10))
   *!*
   m.conttemp = 1
   m.cnome = STREXTRACT(m.lcresponse, [,name:"],[",],m.conttemp)
   DO WHILE !EMPTY(m.cnome)
      *!* Endereço completo
      m.strtemp2 = ALLTRIM(STRTRAN(STREXTRACT(m.lcresponse, [addressLines:["],'"],',m.conttemp),["], ""))
      *!* Extrai o CEP do endereço completo
      m.cep = STRTRAN( GETWORDNUM(m.strtemp2,GETWORDCOUNT(m.strtemp2,","),",") ,"-", "")
      *!* Extrai o endereço, sem o CEP
      m.endereco = ALLTRIM(STRTRAN( LEFT(m.strtemp2, LEN(m.strtemp2)-LEN(m.cep)) , ",", "", ;
         IIF(OCCURS(",",m.strtemp2)<=0,1,OCCURS(",",m.strtemp2))))
      *!* Telefone completo      
      m.strtemp2 = STREXTRACT(m.lcresponse, [phones:[{number:"(0xx)],'"}],',m.conttemp)      
      *!* Extrai o DDD do telefone completo
      ddd = GETWORDNUM(m.strtemp2, 1)
      *!* Extrai o telefone, sem o DDD
      m.telefone = GETWORDNUM(m.strtemp2, 2)
      *!* Insere os dados no cursor
      INSERT INTO (m.nomecursor) (cnome, endereco, cep, ddd, telefone) ;
         VALUES (m.cnome, m.endereco, ALLTRIM(m.cep), m.ddd, m.telefone)
      *!*
      m.conttemp = m.conttemp + 1
      *!* Próximo local encontrado
      m.cnome = STREXTRACT(m.lcresponse, [,name:"],[",],m.conttemp)
   ENDDO
   *!* Retorna o nome do cursor contendo as possíveis informações
   RETURN m.nomecursor
ENDFUNC

Espero que seja útil aos colegas!


Nota: Havendo alguma falha, ou algo que possa ser melhorado, favor comunicar!

[Marcos Guedes]

Segue um exemplo utilizando a rotina (No arquivo encontra-se um aplicativo e o projeto do mesmo):

Clique aqui para realizar o download!

[alceu11]

Bom Dia
Marcos
Desculpe, nao estou conseguindo rodar a pesquisa google mapas
Baixei as dua rotinas, e executei no vfp90, abre um browse, e apos isto nao acontece ]
fecho browse. e nao esta indo buscar


Parabens pelo dowload ja caia num ftp de dowload
Depois o projeto rodei, pede para digitar a busca, digitei west plasa nada aconteceu, morro do careca ai ele achou a rua e o cep,
Pergunto nao tem como abrir a o site do google, com o que eu digitei na busca?

[alceu11]

Marcos
Funcionou, nao estava sabendo usar o aplicativo, por sinal muito bom!!!

Depois de novo teste do projeto coloquei shopping morumbi, apareceu varios resultados,
Entao concluir que tenho que digitar um local especifico, entao desculpe a minha falha, mais porem gostaria se possivel, que tambem abrisse o google com os enderecos encontrados isto e possivel?

[Marcos Guedes]

Marcos
Funcionou, nao estava sabendo usar o aplicativo, por sinal muito bom!!!

Depois de novo teste do projeto coloquei shopping morumbi, apareceu varios resultados,
Entao concluir que tenho que digitar um local especifico, entao desculpe a minha falha, mais porem gostaria se possivel, que tambem abrisse o google com os enderecos encontrados isto e possivel?

Olá, Alceu!
Quanto às pesquisas, tente colocar dados mais específicos.
A rotina se comportada da mesma forma que no seguinte link:
[Você precisa estar registrado e conectado para ver este link.]

Sobre os endereços, estou observando o que mais consigo extrair pois realmente está um pouco complexo.


Qualquer dúvida a mais sobre a rotina é só postar.
Grato pela participação!

[alceu11]

Quanto às pesquisas, tente colocar dados mais específicos.
A rotina se comportada da mesma forma que no seguinte link:
[Você precisa estar registrado e conectado para ver este link.]

Marcos e como fazer para digitar o endereco, e ir direto para o link
com a rua solicitada
no [Você precisa estar registrado e conectado para ver este link.]
??

[Marcos Guedes]

Poderias citar um exemplo de endereço, e também o exemplo de retorno que gostarias de obter?

[alceu11]

Endereco e este
rua santa angela, 68 sao paulo-sp ele retornaria, o link, o mapa e localizacao e os dados
tenta ai?

[alceu11]

marcos estou esperando uma resposta, so quero que abra, o google, com rua que digitei , rua santa angela, 6 sao paulo-sp, preciso urgente!!!
Q

[Marcos Guedes]

Alceu, desculpe-me a demora!
Não sei se é isto que você está precisando:

Código:

abrirpaginagooglemaps("rua santa angela, 6 sao paulo-sp")

PROCEDURE abrirpaginagooglemaps AS void
  LPARAMETERS localizacao AS STRING
  *!*
  LOCAL _open AS HYPERLINK
  LOCAL pcurl AS STRING
  *!*
  m.pcurl = "http://maps.google.com/maps?q=" + ""
  m.pcurl = m.pcurl + m.localizacao + ""
  *!*
  m._open = NEWOBJECT("hyperlink")
  m._open.NAVIGATETO(m.pcurl)
  m._open = NULL
ENDPROC

Resolve?

[alceu11]

isto ai meu camarada, so preciso antes buscar em clientes a rua
pior que na versao 6 nao tem inptubox
da pra melhorar

[alceu11]

Marcos desconsidere a repsosta anterior isto mesmo queria
depois que achou a rua no google
:
print o mapa em um arquivo jpeg
e carregue no em 1 form a imagem do mapa jpeg e mostre na tela
entedeu

[Marcos Guedes]

esta certamente não é uma tarefa fácil, mas você poderia abrir esta página num form contendo um web browser, e o próprio usuário recortar o mapa.

Não serviria?

[alceu11]

Pode ser achei legal, pode demonstrar isto, num form em web brows achei mais pratico, coloque num exemplo form por favor,e se nao encontrar a rua
nao abre o web browse, e diz wait windo ' nao encontrei'.

O web browse nao e demorado nao?
aguardo anciosamente!!

[Marcos Guedes]

Alceu, não utilizo o VFP 6, mas vê se este exemplo funciona:

Clique aqui para fazer o download!

Obs: Testando no VFP 9.0