Clique abaixo para nos ajudar
Login

Esqueci minha senha

Estamos no Facebook
Buscar
 
 

Resultados por:
 


Rechercher Busca avançada

Quem está conectado
10 usuários online :: Nenhum usuário registrado, Nenhum Invisível e 10 Visitantes

Nenhum

[ Ver toda a lista ]


O recorde de usuários online foi de 468 em 1/3/2012, 10:43
Como preencher campos vazios

9/2/2017, 11:55 por Linghston

Pessoal boa tarde,

É o seguinte, eu preciso preencher os campos de uma coluna da tabela DBF que …

Comentários: 2

Enviar msg para WhatsAPP via VFP

7/2/2017, 10:31 por Eliana

Olá Pessoal!

Alguém sabe se é possível enviar mensagem para o WhatsAPP via VFP?


Grata


Comentários: 0

Tudo dá errado

3/2/2017, 16:50 por Douglas Pascini

Troquei de maquina, achei que seria uma boa, [Você precisa estar registrado e conectado para ver esta imagem.]  pois passei para uma maquina melhor.

Instalei o …

Comentários: 1

URGENTE - Instalação do aplicativo

24/1/2017, 08:51 por Douglas Pascini

Bom dia. Estou com um problema, ao fazer a instalação (colocar os arquivo) do aplicativo na …

Comentários: 0

USAR REPORT FORM

30/12/2016, 09:06 por AJC

Pessoal bom dia,
Estou com um grande problema, já pesquisei muita coisa sobre report form, mas o …

Comentários: 3

Estatísticas
Temos 7022 usuários registrados
O último usuário registrado atende pelo nome de Cicero Reis

Os nossos membros postaram um total de 21 mensagens em 12 assuntos

MessageBox estendido

Ver o tópico anterior Ver o tópico seguinte Ir em baixo

Anexo MessageBox estendido

Mensagem por Marcos Guedes em 23/10/2009, 09:54

Personalize seus MESSAGEBOX's como demonstrado nas imagens abaixo:

[Você precisa estar registrado e conectado para ver esta imagem.]

[Você precisa estar registrado e conectado para ver esta imagem.]

Código:
lnOption = MsgBoxEx(;
  "An unexpected error has occurred and the system needs to be restarted" + ;
  CHR(13) + CHR(13) + "What do you want to do ?", ;
  "X", "MsgBoxEx Sample", ;
  "Restart &Now,Restart &Later,&Never Restart")

?lnoption

FUNCTION msgboxex
   LPARAMETERS tccaption, tnicon, tctitle, tcbuttons
   * MSGBOXEX.PRG
   * Modifies the captions of MessageBox buttons
   * Parameters:
   * tcCaption - the text that appears in the dialog box.
   * tnIcon - the icon sign
   * tcTitle - the text that appears in the title bar of the dialog box
   * tcButtons - The captions to be used in the buttons using the comma "," delimiter
   * Use the "&" character to determine the hotkeys to be used - eg: "Option&1,Option&2,Option&3"
   * Needs VFPEX.FLL by CraigBoyd
   * http://www.sweetpotatosoftware.com/spsblog/ct.ashx?id=f7644db8-b155-4d43-8216-4cfde233edb7&url=http%3a%2f%2fwww.sweetpotatosoftware.com%2ffiles%2fvfpex.zip
   * More Info about VFPEX.FLL
   * http://www.sweetpotatosoftware.com/spsblog/2005/08/07/BindEventOnSteroids.aspx
   * Sample:
   * =MsgBoxEx("This is a common text", "!", "Window Title", "Option1,Option2,Option3")

   IF VARTYPE(tntimeout) = "C" AND (PCOUNT() = 4)
      tcbuttons = tntimeout
      tntimeout = 0
   ENDIF
   PRIVATE pnbuttoncnt, pcbuttons, pnbutttype
   pnbuttoncnt = GETWORDCOUNT(tcbuttons, ",")
   pcbuttons = tcbuttons
   *!* Stop 16
   *!* Question 32
   *!* Exclamation 48
   *!* Info 64
   IF VARTYPE(tnicon) = "C"
      tnicon = UPPER(tnicon)
      DO CASE
         CASE tnicon = "X"
            tnicon = 16
         CASE tnicon = "?"
            tnicon = 32
         CASE tnicon = "!"
            tnicon = 48
         CASE tnicon = "I"
            tnicon = 64
         OTHERWISE
            tnicon = 0
      ENDCASE
   ENDIF

   *!* Windows Hook constants
   #DEFINE wh_cbt 5
   *!* Set library so BindEventEx and UnBindEventEx can be used in VFP
   LOCAL lcoldsetlib
   lcoldsetlib = SET("Library")
   SET LIBRARY TO (LOCFILE("vfpex.fll"))
   bindeventex('wineventhandler()', wh_cbt) && SetWindowsHookEx
   *!* This messagebox will be modified before it is shown
   LOCAL lnoption, lnindex

   DO CASE
      CASE pnbuttoncnt = 1
         pnbutttype = 0 && Ok
      CASE pnbuttoncnt = 2
         pnbutttype = 4 && Yes / No
      CASE pnbuttoncnt = 3
         pnbutttype = 2 && Abort / Retry / Ignore
      OTHERWISE
   ENDCASE

   lnoption = MESSAGEBOX(tccaption, tnicon + pnbutttype, tctitle)
   LOCAL lnoffset
   lnoffset = ICASE(pnbuttoncnt = 3, 2, pnbuttoncnt = 2, 5 , 0)
   lnindex = lnoption - lnoffset

   IF NOT EMPTY(lcoldsetlib)
      SET LIBRARY TO (lcoldsetlib)
   ENDIF
   RETURN lnindex
ENDFUNC


PROCEDURE wineventhandler
   IF ncode == 5
      LOCAL N, lnoffset
      lnoffset = ICASE(pnbuttoncnt = 3, 2, pnbuttoncnt = 2, 5 , 0)

      FOR N = 1 TO pnbuttoncnt
         xmbsetdlgitemtext(wparam, lnoffset + N, GETWORDNUM(pcbuttons, N, ","))
      ENDFOR
      xmbcallnexthookex(hhook, ncode, wparam, LPARAM) && all 4 variables exist
      unbindeventex()
   ELSE
      xmbcallnexthookex(hhook, ncode, wparam, LPARAM) && all 4 variables created by FLL
   ENDIF
   RELEASE ncode, wparam, LPARAM, hhook
ENDPROC

*********************************************************************
FUNCTION xmbsetdlgitemtext(hdlg, niddlgitem, lpstring)
   *********************************************************************
   DECLARE INTEGER SetDlgItemText IN user32 AS xmbSetDlgItemText ;
      LONG hDlg,;
      LONG nIDDlgItem,;
      STRING lpString
   RETURN xmbsetdlgitemtext(hdlg, niddlgitem, lpstring)
ENDFUNC

*********************************************************************
FUNCTION xmbcallnexthookex(hhook, ncode, wparam, LPARAM)
   *********************************************************************
   DECLARE LONG CallNextHookEx IN user32 AS xmbCallNextHookEx ;
      LONG hHook, LONG nCode, LONG wParam, LONG LPARAM
   RETURN xmbcallnexthookex(hhook, ncode, wparam, LPARAM)
ENDFUNC

Obs: Esta solução foi postada por César Chalom no Grupo FOX Brasil!
Fonte: [Você precisa estar registrado e conectado para ver este link.]

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: MessageBox estendido

Mensagem por Marcos Guedes em 26/10/2009, 10:07

Novas atualizações!

Agora permite:
  • Trocar os captions dos botões
  • Desabilitar botões
  • Trocar o ícone principal do messagebox


Exemplos:

[Você precisa estar registrado e conectado para ver esta imagem.]
Código:
lnoption = msgboxex( ;
   "You have entered a wrong password for 5 times." + CHR(13) + ;
   "For security reasons this login was suspended.", ; && Main message
0, ; && Default icon info
"password incorrect", ; && Title bar caption
"\&retry,&exit,get &new pwd", ; && New button captions
"41.ico") && Icon file

[Você precisa estar registrado e conectado para ver esta imagem.]
Código:
lnoption = msgboxex(;
   "An unexpected error has occurred and the system needs to be restarted" + ;
   CHR(13) + CHR(13) + "What do you want to do ?", ;
   "X", ;
   "MsgBoxEx Sample", ;
   "Restart &Now,Restart &Later,&Never Restart")

[Você precisa estar registrado e conectado para ver esta imagem.]
Código:
lnoption = msgboxex( ;
   "Could not find the file 'Import.csv' in the selected folder", ;
   0, ;
   "File not found", ;
   "&Abort,\&Retry,Change folder", ;
   "17.ico")

A rotina:
Código:
FUNCTION msgboxex
   LPARAMETERS tccaption, tnicon, tctitle, tcbuttons, tciconfile
   * MSGBOXEX.PRG
   * Description: Modifies the captions of MessageBox buttons
   * Prerequisites: Needs VFPEX.FLL by CraigBoyd
   * http://www.sweetpotatosoftware.com/spsblog/ct.ashx?id=f7644db8-b155-4d43-8216-4cfde233edb7&url=http%3a%2f%2fwww.sweetpotatosoftware.com%2ffiles%2fvfpex.zip
   * More Info about VFPEX.FLL
   * http://www.sweetpotatosoftware.com/spsblog/2005/08/07/BindEventOnSteroids.aspx
   * Parameters:
   * tcCaption - the text that appears in the dialog box.
   * tnIcon - the icon sign
   * tcTitle - the text that appears in the title bar of the dialog box
   * tcButtons - The captions to be used in the buttons using the comma "," delimiter
   * Use the "&" character to determine the hotkeys to be used - eg: "Option&1,Option&2,Option&3"
   * Use a "\" to disable the button
   * tcIconFile - the icon file to replace the default from MessageBox()
   * Returns: the index number according to the option selected - eg. returns the value 3 if the 3rd button was selected.
   * Sample:
   * =MsgBoxEx("This is a common text", "!", "Window Title", "Option1,Option2,Option3")
   IF VARTYPE(tntimeout) = "C" AND (PCOUNT() = 4)
      tcbuttons = tntimeout
      tntimeout = 0
   ENDIF

   PRIVATE pnbuttoncnt, pcbuttons, pnbutttype, pciconfile, phicon
   pciconfile = IIF(EMPTY(tciconfile),"", tciconfile)
   pnbuttoncnt = GETWORDCOUNT(tcbuttons, ",")
   pcbuttons = tcbuttons
   *!* Stop 16
   *!* Question 32
   *!* Exclamation 48
   *!* Info 64
   IF VARTYPE(tnicon) = "C"
      tnicon = UPPER(tnicon)
      DO CASE
         CASE tnicon = "X"
            tnicon = 16
         CASE tnicon = "?"
            tnicon = 32
         CASE tnicon = "!"
            tnicon = 48
         CASE tnicon = "I"
            tnicon = 64
         OTHERWISE
            tnicon = 0
      ENDCASE
   ENDIF

   * Check if an icon will be shown
   * If an icon file was passed, we need to ensure that MessageBox() will
   * show an icon, that will be changed further.

   #DEFINE image_bitmap 0
   #DEFINE image_icon 1
   #DEFINE lr_loadfromfile 0x0010
   #DEFINE lr_defaultsize 0x0040
   phicon = 0
   IF NOT EMPTY(pciconfile) AND ;
         (NOT (BITTEST(tnicon, 4) OR BITTEST(tnicon, 5) OR BITTEST(tnicon, 6)))
      tnicon = tnicon + 16
      phicon = xmbloadimage(0, FULLPATH(pciconfile), image_icon,;
         0,0, lr_loadfromfile + lr_defaultsize)
   ENDIF


   * Windows Hook constants
   #DEFINE wh_cbt 5

   * Set library so BindEventEx and UnBindEventEx can be used in VFP
   LOCAL lcoldsetlib
   lcoldsetlib = SET("Library")
   SET LIBRARY TO (LOCFILE("vfpex.fll"))
   bindeventex('wineventhandler()', wh_cbt) && SetWindowsHookEx

   * This messagebox will be modified before it is shown
   LOCAL lnoption, lnindex
   DO CASE
      CASE pnbuttoncnt = 1
         pnbutttype = 0 && Ok
      CASE pnbuttoncnt = 2
         pnbutttype = 4 && Yes / No
      CASE pnbuttoncnt = 3
         pnbutttype = 2 && Abort / Retry / Ignore
      OTHERWISE
   ENDCASE

   lnoption = MESSAGEBOX(tccaption, tnicon + pnbutttype, tctitle)

   LOCAL lnoffset
   lnoffset = ICASE(pnbuttoncnt = 3, 2, pnbuttoncnt = 2, 5 , 0)
   lnindex = lnoption - lnoffset

   IF phicon <> 0
      =xmbdeleteobject(phicon) && Clear icon handle
   ENDIF

   IF NOT EMPTY(lcoldsetlib)
      SET LIBRARY TO (lcoldsetlib)
   ENDIF
   RETURN lnindex
ENDFUNC


PROCEDURE wineventhandler
   #DEFINE dlg_ctrlid_icon 0x0014
   #DEFINE stm_seticon 0x0170
   #DEFINE stm_setimage 0x0172
   IF ncode == 5
      IF NOT EMPTY(phicon)
         * Changing the Dialog icon
         LOCAL lhiconwindow
         lhiconwindow = xmbgetdlgitem(wparam, dlg_ctrlid_icon)
         IF lhiconwindow <> 0
            IF phicon <> 0
               =xmbsendmessage(lhiconwindow, stm_seticon, phicon, 0)
            ENDIF
         ENDIF
      ENDIF

      * Change button attributes
      LOCAL N, lnoffset, lccaption
      lnoffset = ICASE(pnbuttoncnt = 3, 2, pnbuttoncnt = 2, 5 , 0)
      FOR N = 1 TO pnbuttoncnt
         lccaption = GETWORDNUM(pcbuttons, N, ",")
         * Disable current button
         IF LEFT(lccaption, 1) = "\"
            lccaption = SUBSTR(lccaption, 2) && Get the rest of the string
            LOCAL lnbtnhwnd
            lnbtnhwnd = xmbgetdlgitem(wparam, lnoffset + N)
            =xmbenablewindow(lnbtnhwnd, 0)
         ENDIF

         * Change the caption
         =xmbsetdlgitemtext(wparam, lnoffset + N, lccaption)
      ENDFOR

      =xmbcallnexthookex(hhook, ncode, wparam, LPARAM) && all 4 variables exist
      unbindeventex()
   ELSE
      =xmbcallnexthookex(hhook, ncode, wparam, LPARAM) && all 4 variables created by FLL
   ENDIF

   RELEASE ncode, wparam, LPARAM, hhook
ENDPROC



*********************************************************************
FUNCTION xmbsetdlgitemtext(hdlg, niddlgitem, lpstring)
   *********************************************************************
   DECLARE INTEGER SetDlgItemText IN user32 AS xmbSetDlgItemText ;
      LONG hDlg,;
      LONG nIDDlgItem,;
      STRING lpString
   RETURN xmbsetdlgitemtext(hdlg, niddlgitem, lpstring)
ENDFUNC

*********************************************************************
FUNCTION xmbcallnexthookex(hhook, ncode, wparam, LPARAM)
   *********************************************************************
   DECLARE LONG CallNextHookEx IN user32 AS xmbCallNextHookEx ;
      LONG hHook, LONG nCode, LONG wParam, LONG LPARAM
   RETURN xmbcallnexthookex(hhook, ncode, wparam, LPARAM)
ENDFUNC

*********************************************************************
FUNCTION xmbgetdlgitem(hdlg, niddlgitem)
   *********************************************************************
   * hDlg [in] Handle to the dialog box that contains the control.
   * nIDDlgItem [in] Specifies the identifier of the control to be retrieved.
   * http://msdn.microsoft.com/en-us/library/ms645481(VS.85).aspx
   DECLARE INTEGER GetDlgItem IN user32 AS xmbGetDlgItem ;
      LONG hDlg,;
      LONG nIDDlgItem
   RETURN xmbgetdlgitem(hdlg, niddlgitem)
ENDFUNC

*********************************************************************
FUNCTION xmbenablewindow(HWND, fenable)
   *********************************************************************
   DECLARE INTEGER EnableWindow IN user32 AS xmbEnableWindow INTEGER HWND, INTEGER fEnable
   RETURN xmbenablewindow(HWND, fenable)
ENDFUNC

*********************************************************************
FUNCTION xmbsendmessage(hwindow, msg, wparam, LPARAM)
   *********************************************************************
   * http://msdn.microsoft.com/en-us/library/bb760780(VS.85).aspx
   * http://www.news2news.com/vfp/?group=-1&function=312
   DECLARE INTEGER SendMessage IN user32 AS xmbSendMessage;
      INTEGER hWindow, INTEGER Msg,;
      INTEGER wParam, INTEGER LPARAM
   RETURN xmbsendmessage(hwindow, msg, wparam, LPARAM)
ENDFUNC

*********************************************************************
FUNCTION xmbloadimage(hinst, lpszname, utype, cxdesired, cydesired, fuload)
   *********************************************************************
   DECLARE INTEGER LoadImage IN user32 AS xmbLoadImage;
      INTEGER hinst,;
      STRING lpszName,;
      INTEGER uType,;
      INTEGER cxDesired,;
      INTEGER cyDesired,;
      INTEGER fuLoad
   RETURN xmbloadimage(hinst, lpszname, utype, cxdesired, cydesired, fuload)
ENDFUNC

*********************************************************************
FUNCTION xmbdeleteobject(hobject)
   *********************************************************************
   DECLARE INTEGER DeleteObject IN gdi32 AS xmbDeleteObject INTEGER hObject
   RETURN xmbdeleteobject(hobject)
ENDFUNC

Fonte:
[Você precisa estar registrado e conectado para ver este link.]

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: MessageBox estendido

Mensagem por Marcos Guedes em 26/10/2009, 10:11

Download da FLL:
[Você precisa estar registrado e conectado para ver este link.]

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Ver o tópico anterior Ver o tópico seguinte Voltar ao Topo


 
Permissão deste fórum:
Você não pode responder aos tópicos neste fórum