Clique abaixo para nos ajudar
Conectar-se

Esqueci minha senha

Estamos no Facebook
Buscar
 
 

Resultados por:
 


Rechercher Busca avançada

Quem está conectado
11 usuários online :: Nenhum usuário registrado, Nenhum Invisível e 11 Visitantes :: 1 Motor de busca

Nenhum

[ Ver toda a lista ]


O recorde de usuários online foi de 468 em 1/3/2012, 10:43
Espessura do cursor intermitente

7/3/2017, 09:08 por Jefferson Matakas

Bom dia a todos !!

Existe uma opcao no windows que pode ser acessada atraves da 'central da …

Comentários: 0

DESENVOLVIMENTO EM REDES

4/3/2017, 18:45 por AJC

Pessoal tem ou conhece livros ou material para programação em
redes usando banco de dados nativo …

Comentários: 0

USAR REPORT FORM

30/12/2016, 09:06 por AJC

Pessoal bom dia,
Estou com um grande problema, já pesquisei muita coisa sobre report form, mas o …

Comentários: 4

Como preencher campos vazios

9/2/2017, 11:55 por Linghston

Pessoal boa tarde,

É o seguinte, eu preciso preencher os campos de uma coluna da tabela DBF que …

Comentários: 2

Enviar msg para WhatsAPP via VFP

7/2/2017, 10:31 por Eliana

Olá Pessoal!

Alguém sabe se é possível enviar mensagem para o WhatsAPP via VFP?


Grata


Comentários: 0

Estatísticas
Temos 7037 usuários registrados
O último usuário registrado atende pelo nome de GETULIO

Os nossos membros postaram um total de 31 mensagens em 17 assuntos

Internet + VFP

Ver o tópico anterior Ver o tópico seguinte Ir em baixo

Anexo Internet + VFP

Mensagem por Marcos Guedes em 16/10/2009, 13:08

Segue um código muito útil para tratar de funcionalidas web.
Entre as demais funções, este código permite a leitura do código fonte de uma páginas web:
Código:
* readurl.prg 06-Mar-98

* 06-Mar-98 pulled from Q174524 on March 98 Technet CD
* 06-Mar-98 bug fixed about the length of the sReadBuffer
* 20-Apr-06 Added support for POST

*Any Internet or intranet URL can be passed as a parameter. Microsoft.com
*was chosen for this example.

*Note that Microsoft Internet Explorer must be installed on the computer.

* passed: URLName, in the form "http://www.microsoft.com"
*
* returns: the content of the URL
*
* usage:
*
* uWebContent = ReadURL( "http://www.microsoft.com" )
* uWebContent = ReadURL( "http://www.SomeSite.com/SomeJPG.jpg" )
* This next one provides feedback on the download every 4092 bytes:
* uWebContent = ReadURL( "http://www.SomeSite.com/SomeBigFile.exe",
* "GiveFeedback(lnBytesRead,llOK)", 4092 )
*
* Useful variables to pass to the Feedback Function:
* lnTotalBytesRead -- The total bytes that have been read
* lnBytesRead -- The number of bytes read this last iteration
* lcReadBuffer -- The data that was just read this last iteration
* llOK -- The "OK to continue" flag. Set this false in the function to stop the download.
* lnBytesAvail -- The amount of data that is ready to download
* lnApparentSize -- lnBytesAvail + lnTotalBytesRead
* (there is no way to tell how much more data the server will send!)
* lnSize -- Content Length returned by QueryInfo
* lcStatus -- A description string stating the current status of the connection.
* lhInternetSession
* lhUrlFile
* lhConnect
*
* notes:
* 1 - IE does not need to be running to use this, but must be installed

LPARAMETERS pcurlname, pcoptfeedback, pnoptbuffsize, pcoptoutputfile, pcoptuser, pcoptpwd, pcoptpostdata
* These parameters are No good, pcOptOutputBuffer, pcOptOutputWhole
* because once they're passed as parameters, the original names get hidden, so the
* feedback function can't reference them that way, anyway.
*May 27, 03: Loader v1.01: Added parameter "pcOptOutputFile" to be able to download
* files bigger than 16MB
*Jan 29, 04: LASv11.01/LWMv10.44 wgcs: Added optional User & Pwd params to facilitate Good HTTP AUTH

DECLARE INTEGER InternetOpen IN wininet.DLL STRING sAgent, ;
   INTEGER lAccessType, STRING sProxyName, ;
   STRING sProxyBypass, INTEGER lFlags

DECLARE INTEGER InternetOpenUrl IN wininet.DLL ;
   INTEGER hInternetSession, STRING sUrl, STRING sHeaders, ;
   INTEGER lHeadersLength, INTEGER lFlags, INTEGER lContext

DECLARE INTEGER InternetReadFile IN wininet.DLL INTEGER hfile, ;
   STRING @sBuffer, INTEGER lNumberofBytesToRead, INTEGER @lBytesRead

DECLARE SHORT InternetSetOption IN wininet.DLL ;
   INTEGER HINTERNET_hInternetSession, ;
   LONG DWORD_dwOption, ;
   STRING @ LPVOID_lpBuffer, ;
   LONG DWORD_dwBufferLength

DECLARE INTEGER InternetConnect IN wininet;
   INTEGER hInternetSession,;
   STRING sServerName,;
   LONG nServerPort,;
   STRING sUsername,;
   STRING sPassword,;
   LONG lService,;
   LONG lFlags,;
   LONG lContext

DECLARE INTEGER HttpOpenRequest IN wininet;
   INTEGER hConnect,;
   STRING lpszVerb,;
   STRING lpszObjectName,;
   STRING lpszVersion,;
   STRING lpszReferer,;
   INTEGER lpszAcceptTypes,;
   INTEGER dwFlags,;
   INTEGER dwContext
DECLARE INTEGER HttpSendRequest IN wininet;
   INTEGER hRequest,;
   INTEGER lpszHeaders,;
   INTEGER dwHeadersLength,;
   STRING @ lpOptional,;
   INTEGER dwOptionalLength
DECLARE INTEGER HttpQueryInfo IN wininet;
   INTEGER hRequest,;
   LONG dwInfoLevel,;
   STRING @ lpvBuffer,;
   LONG @ lpdwBufferLength,;
   LONG @ lpdwIndex
DECLARE INTEGER InternetQueryDataAvailable IN wininet ;
   INTEGER HINTERNET_hFile, ;
   LONG @ LPDWORD_lpdwNumberOfBytesAvailable, ;
   LONG @ DWORD_dwFlags, ;
   LONG @ DWORD_dwContext

DECLARE short InternetCloseHandle IN wininet.DLL INTEGER hInst
DECLARE LONG GetLastError IN Win32Api
DECLARE SHORT InternetGetLastResponseInfo IN wininet.DLL ;
   LONG @ LPDWORD_lpdwError, ;
   STRING @ LPTSTR_lpszBuffer, ;
   LONG @ LPDWORD_lpdwBufferLength

#DEFINE internet_service_url 0
#DEFINE internet_service_ftp 1
#DEFINE internet_service_gopher 2
#DEFINE internet_service_http 3

#DEFINE internet_open_type_preconfig 0
#DEFINE internet_open_type_direct 1
#DEFINE internet_open_type_proxy 3
#DEFINE synchronous 0
#DEFINE internet_flag_async 0x10000000

*!* #define INTERNET_FLAG_RELOAD 0x80000000 // retrieve the original item
*!* #define INTERNET_FLAG_SECURE 0x00800000 // use PCT/SSL if applicable (HTTP)
*!* #define INTERNET_FLAG_KEEP_CONNECTION 0x00400000 // use keep-alive semantics
*!* #define INTERNET_FLAG_NO_AUTO_REDIRECT 0x00200000 // don't handle redirections automatically
*!* #define INTERNET_FLAG_READ_PREFETCH 0x00100000 // do background read prefetch
*!* #define INTERNET_FLAG_NO_COOKIES 0x00080000 // no automatic cookie handling
*!* #define INTERNET_FLAG_NO_AUTH 0x00040000 // no automatic authentication handling
*!* #define INTERNET_FLAG_CACHE_IF_NET_FAIL 0x00010000 // return cache file if net request fails

*#DEFINE INTERNET_FLAG_RELOAD 2147483648
#DEFINE internet_flag_reload 0x80000000
#DEFINE internet_flag_keep_connection 0x00400000

#DEFINE internet_option_username 28
#DEFINE internet_option_password 29
#DEFINE internet_option_proxy 38
#DEFINE internet_option_proxy_username 43
#DEFINE internet_option_proxy_password 44

#DEFINE internet_option_connect_timeout 2
#DEFINE internet_option_connect_retries 3

#DEFINE http_query_content_length 5

LOCAL lhinternetsession, lhurlfile, lhconnect, ;
   lcagent, lnok, lcretval, ladr[1], llcancel, lnres1, lnres2, ;
   llok, lntotalbytesread, lnbytesread, lcreadbuffer, lnbytesavail, lnapparentsize, ;
   lnsize, lcbuf, lnbuflen, lnvoid, lnqryret, lcstatus, lnerr

lcreadbuffer = '' && Clear before first feedback!!
lcstatus = 'Initializing...'
IF VARTYPE(pcoptfeedback)='C'
   * if we're given a feedback function, make sure it has both parentheses (looks like a function)
   IF NOT ( AT('(',pcoptfeedback)>0 AND (AT('(',pcoptfeedback) < AT(')',pcoptfeedback) ) )
      pcoptfeedback = .F.
   ENDIF
ENDIF

* what application is using Internet services?
lcagent = "VFP"
STORE 0 TO lhinternetsession, lhurlfile, lhconnect, ;
   lnapparentsize, lnsize, lntotalbytesread, lnbytesavail

lcstatus = 'Opening Internet API...'
IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
   =&pcoptfeedback
ENDIF

lhinternetsession = internetopen( lcagent, internet_open_type_preconfig, '', '', synchronous )

* Cannot do asynchronous operations without a Callback function:
*lhInternetSession = InternetOpen( lcAgent, INTERNET_OPEN_TYPE_PRECONFIG, '', '', INTERNET_FLAG_ASYNC )

IF lhinternetsession = 0
   lnerr = getlasterror() && Sep 9, 2005
   lcstatus = 'Error: Internet session cannot be established. (Err#'+TRANSFORM(lnerr)+')'
   IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
      =&pcoptfeedback
   ELSE
      WAIT WINDOW lcstatus TIME 2
   ENDIF
   RETURN .NULL.
ENDIF
lcstatus = "Internet session opened"
IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
   =&pcoptfeedback
ENDIF

&& LASv11.01/LWMv10.44 wgcs
IF VARTYPE(pcoptuser)='C' AND VARTYPE(pcoptpwd)='C'
   LOCAL lcuser, lcpwd, lchost, lcobj, lnret
   lcuser = pcoptuser+CHR(0)
   lcpwd = pcoptpwd+CHR(0)
   * Set the Internet options:
   internetsetoption( lhinternetsession, internet_option_username, @lcuser, LEN(lcuser) )
   internetsetoption( lhinternetsession, internet_option_password, @lcpwd, LEN(lcpwd) )

   * Connect to host. Parse the URL
   lchost = SUBSTR( pcurlname, AT("://", pcurlname)+3 )
   IF '/' $ lchost
      lcobj = SUBSTR( lchost, AT('/',lchost) )
      lchost = LEFT( lchost, AT('/',lchost)-1 )
   ELSE
      lcobj = '/'
   ENDIF

   lcstatus = "Creating Internet Connection..."
   IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
      =&pcoptfeedback
   ENDIF

   lhconnect = internetconnect( lhinternetsession, lchost, 0, lcuser, lcpwd, internet_service_http, 0, 0 )
   *!* hInternet, // wininet handle,
   *!* pszHost, // host
   *!* 0, // port
   *!* pszUser, // user
   *!* NULL, // pass
   *!* INTERNET_SERVICE_HTTP, // service
   *!* 0, // flags
   *!* 0 // context
   IF lhconnect=0
      lnerr = getlasterror() && Feb 4, 2006, WebMan v14.03
      lcstatus = 'Error: Connection to host "'+lchost+'" cannot be established. (Err#'+TRANSFORM(lnerr)+')'
      IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
         =&pcoptfeedback
      ELSE
         WAIT WINDOW lcstatus TIMEOUT 2
      ENDIF
      internetclosehandle( lhinternetsession ) && LASv11.01/LWMv10.44 wgcs
      RETURN .NULL.
   ENDIF
   *!* This originally somehow always passed a blank password to InternetConnect, then set the password below... I don't know why
   *!* if empty( lcPwd )
   *!* * // Work around InternetConnect disallowing empty passwords.
   *!* InternetSetOption( hConnect, INTERNET_OPTION_PASSWORD, pszPass, lstrlen(pszPass)+1);
   *!* ENDIF

   lcstatus = 'Opening HTTP Request...'
   IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
      =&pcoptfeedback
   ENDIF

   *// flags: keep-alive || bypass cache
   lhurlfile = httpopenrequest( lhconnect, 'GET', lcobj, 0, 0, 0, ;
      BITOR( internet_flag_keep_connection, internet_flag_reload ), 0 )
   *!* hConnect, // connect handle
   *!* "GET", // request method
   *!* pszObject, // object name
   *!* NULL, // version
   *!* NULL, // referrer
   *!* NULL, // accept types
   *!* INTERNET_FLAG_KEEP_CONNECTION // flags: keep-alive
   *!* | INTERNET_FLAG_RELOAD, // flags: bypass cache
   *!* 0 // context
   IF lhurlfile=0
      lnerr = getlasterror() && Feb 4, 2006, WebMan v14.03
      lcstatus = 'Error: Request to host "'+lchost+'" cannot be opened. (Err #'+TRANSFORM(lnerr)+')'
      IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
         =&pcoptfeedback
      ELSE
         WAIT WINDOW lcstatus TIMEOUT 2
      ENDIF
      internetclosehandle( lhconnect ) && Sept 9, 2005: Moved closing lhConnect above lhInternetSession
      internetclosehandle( lhinternetsession )
      RETURN .NULL.
   ENDIF
   lcstatus = "HTTP Request Opened. Sending Request..."
   IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
      =&pcoptfeedback
   ENDIF

   *// Send request.
   IF VARTYPE(pcoptpostdata)='C' AND NOT EMPTY(pcoptpostdata)
      lnret = httpsendrequest( lhurlfile, 0, 0, @pcoptpostdata, LEN(pcoptpostdata) )
   ELSE
      lnret = httpsendrequest( lhurlfile, 0, 0, '', 0 )
   ENDIF
   *!* hRequest, // request handle
   *!* "", // header string
   *!* 0, // header length
   *!* NULL, // post data
   *!* 0 // post length
   *// Handle any authentication dialogs.
   * if (NeedAuth(hRequest) && fAllowCustomUI)
   * do custom UI
   * while (InternetReadFile (hRequest, bBuf, cbBuf, &cbRead) && cbRead)
   * fwrite (bBuf, 1, cbRead, stdout);

   IF lnret = 0
      * URL cannot be opened
      lnerr = getlasterror() && Feb 4, 2006, WebMan v14.03
      lcstatus = 'Error: Cannot Send Request. (Err#'+TRANSFORM(lnerr)+')'
      IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
         =&pcoptfeedback
      ELSE
         WAIT WINDOW lcstatus TIMEOUT 2
      ENDIF
      internetclosehandle( lhurlfile ) && Sept 9, 2005: Wasn't closing lhUrlFile
      internetclosehandle( lhconnect )
      internetclosehandle( lhinternetsession )
      RETURN .NULL.
   ENDIF

   lcstatus = "HTTP Request Sent"
   IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
      =&pcoptfeedback
   ENDIF
ELSE &&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
   lcstatus = "Opening URL..."
   IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
      =&pcoptfeedback
   ENDIF

   lhurlfile = internetopenurl( lhinternetsession, pcurlname, '', 0, internet_flag_reload, 0 )

   IF lhurlfile = 0
      * URL cannot be opened
      lnerr = getlasterror() && Sep 9, 2005..display extended error information:
      *lcStatus = 'Error: Cannot open URL "'+pcUrlName+'"'+CHR(13);
      * +' (Error #'+TRANSFORM(lnErr)+')'
      lcstatus = 'Error: Cannot open URL. (Err #'+TRANSFORM(lnerr)+')'
      *v1.14 lnErr2 = 0
      *v1.14 lcMsg = SPACE(1000)
      *v1.14 lnLen = 1000
      *v1.14 lnRes = InternetGetLastResponseInfo( @lnErr2, @lcMsg, @lnLen )
      *v1.14 IF lnRes=0
      *v1.14 lnErr = GetLastError() && Sep 9, 2005
      *v1.14 lcStatus = lcStatus + CHR(13) + '(Error getting last response: '+TRANSFORM(lnErr)+')'
      *v1.14 ELSE
      *v1.14 lcStatus = lcStatus + CHR(13) + 'Last response: '+TRANSFORM(lnErr2)+' '+LEFT(lcMsg,lnLen)
      *v1.14 ENDIF

      IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
         =&pcoptfeedback
      ELSE
         WAIT WINDOW lcstatus TIMEOUT 2
      ENDIF
      internetclosehandle( lhinternetsession ) && LASv11.01/LWMv10.44 wgcs
      RETURN .NULL.
   ENDIF

   lcstatus = "URL Opened"
   IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
      =&pcoptfeedback
   ENDIF
ENDIF

* 01/26/2005: wgcs: try to get the size of the resource:
lcbuf = REPLICATE(' ',40)
lnbuflen = 40
lnvoid = 0
lnqryret = httpqueryinfo( lhurlfile, http_query_content_length, ;
   @lcbuf, @lnbuflen, @lnvoid )
IF lnqryret=1
   lnsize = VAL(lcbuf)
   * lnSize = buf2dword(lcBuf)
ENDIF
**

lcretval = ""
llok = .T.
llcancel = .F.
lntotalbytesread = 0
lnbytesread = 0
lcreadbuffer = ''

lcstatus = "Starting to Read File..."
IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
   =&pcoptfeedback
ENDIF

* Clear output file, if it exists.
IF TYPE('pcOptOutputFile')='C' AND ADIR(ladr,pcoptoutputfile)>0
   DELETE FILE (pcoptoutputfile)
ENDIF

DO WHILE llok AND NOT llcancel
   * set aside a big buffer
   lcreadbuffer = SPACE(IIF(VARTYPE(pnoptbuffsize)='N',pnoptbuffsize,32767))
   lnbytesread = 0
   lnok = internetreadfile( lhurlfile, @lcreadbuffer, LEN(lcreadbuffer), @lnbytesread)

   lntotalbytesread = lntotalbytesread + lnbytesread

   IF ( lnbytesread > 0 )
      IF TYPE('pcOptOutputFile')='C'
         STRTOFILE(LEFT(lcreadbuffer,lnbytesread),pcoptoutputfile,.T.) && Add to file.
      ELSE
         lcretval = lcretval + LEFT( lcreadbuffer, lnbytesread )
      ENDIF
   ENDIF

   * error trap - either a read failure or read past eof()
   llok = ( lnok = 1 ) AND ( lnbytesread > 0 )

   lnbytesavail = 0
   lnres1 = 0
   lnres2 = 0
   lnok = internetquerydataavailable( lhurlfile, @lnbytesavail, @lnres1, @lnres2 )
   *!* INTEGER HINTERNET_hFile, ;
   *!* LONG @ LPDWORD_lpdwNumberOfBytesAvailable, ;
   *!* LONG @ DWORD_dwFlags, ;
   *!* LONG @ DWORD_dwContext
   IF lnok=1
      lnapparentsize = lntotalbytesread+lnbytesavail
   ENDIF

   IF VARTYPE(pcoptfeedback)='C'
      lcstatus = "Reading File..."
      IF NOT &pcoptfeedback
         llcancel = .T.
      ENDIF
   ENDIF
ENDDO

* close all the handles we opened
internetclosehandle( lhurlfile )
IF lhconnect>0
   internetclosehandle( lhconnect )
ENDIF
internetclosehandle( lhinternetsession )

lcstatus = "Finished Reading"
IF VARTYPE(pcoptfeedback)='C' && Call the feedback at the zero mark
   =&pcoptfeedback
ENDIF

* IF saving to file, return Success status.
IF TYPE('pcOptOutputFile')='C'
   RETURN NOT llcancel
ENDIF
* return the URL contents
RETURN lcretval


FUNCTION buf2dword(lcbuffer)
   RETURN ASC(SUBSTR(lcbuffer, 1,1)) + ;
      BITLSHIFT(ASC(SUBSTR(lcbuffer, 2,1)), 8) +;
      BITLSHIFT(ASC(SUBSTR(lcbuffer, 3,1)), 16) +;
      BITLSHIFT(ASC(SUBSTR(lcbuffer, 4,1)), 24)
ENDFUNC
Encontrado no link abaixo:
[Você precisa estar registrado e conectado para ver este link.]

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Internet + VFP

Mensagem por Tales Ruan em 17/10/2009, 10:00

Opa!

EXATAMENTE o que eu estava procurando! Só falta testar.

Notei que tem um comentário no código fonte que diz que precisa do Internet Explorer instalado no computador. Felizmente isso não é um problema, no Windows.

Valeu Marcos! Depois conto como funcionou. Flw
avatar
Tales Ruan
Participa Bastante
Participa Bastante


Voltar ao Topo Ir em baixo

Anexo Re: Internet + VFP

Mensagem por RafaelSegat em 13/1/2010, 07:45

Quais são os valores que se passa nos parametros?

LPARAMETERS pcurlname, pcoptfeedback, pnoptbuffsize, pcoptoutputfile, pcoptuser, pcoptpwd, pcoptpostdata
avatar
RafaelSegat
Participante Regular
Participante Regular


Voltar ao Topo Ir em baixo

Anexo Re: Internet + VFP

Mensagem por Marcos Guedes em 13/1/2010, 11:46

[Você precisa estar registrado e conectado para ver este link.] escreveu:Quais são os valores que se passa nos parametros?

LPARAMETERS pcurlname, pcoptfeedback, pnoptbuffsize, pcoptoutputfile, pcoptuser, pcoptpwd, pcoptpostdata
Amigo, não tenho como te responder com precisão quais valores que passamos como parâmetro, mas você poderá encontrar muitos detalhes de como utilizar esta função dando uma lida nos comentários.

Até agora só utilizei a mesma para ler um conteúdo de uma URL e baixar arquivos.

Lendo conteúdo:
uWebContent = ReadURL( "http://www.microsoft.com" )
STRTOFILE(uWebContent,'arquivo.txt')

Baixando arquivo:
uWebContent = ReadURL( "http://www.SomeSite.com/SomeJPG.jpg" )
STRTOFILE(uWebContent,'SomeJPG.jpg')

Os parâmetros "pcoptuser" e "pcoptpwd" dá-me a entender que é possível acessar algum endereço [Você precisa estar registrado e conectado para ver este link.]
Porém ainda não tive tempo de testar.

E caso você precise ler o retorno do download, você poderá fazer o seguinte:

*!* Solicita o arquivo para download
uwebcontent = readurl( "http://www.SomeSite.com/SomeBigFile.exe", ;
"GiveFeedback(lnTotalBytesRead, lnBytesRead, lcReadBuffer, llOK, lnBytesAvail, ;
lnApparentSize, lnSize, lcStatus, lhInternetSession, lhUrlFile, lhConnect)" )

Adicione ao arquivo a seguinte função, como exemplo:
Código:
PROCEDURE givefeedback AS void
   LPARAMETERS ;
      lntotalbytesread, lnbytesread, ;
      lcreadbuffer, llok, ;
      lnbytesavail, lnapparentsize, ;
      lnsize, lcstatus, ;
      lhinternetsession, lhurlfile, ;
      lhconnect

   STRTOFILE("lnTotalBytesRead: " + TRANSFORM(lntotalbytesread)+CHR(13)+CHR(10),'teste.txt',1)
   STRTOFILE("lnBytesRead: " + TRANSFORM(lnbytesread)+CHR(13)+CHR(10),'teste.txt',1)

   STRTOFILE("lcReadBuffer: " + TRANSFORM(lcreadbuffer)+CHR(13)+CHR(10),'teste.txt',1)
   STRTOFILE("llOK: " + TRANSFORM(llok)+CHR(13)+CHR(10),'teste.txt',1)

   STRTOFILE("lnBytesAvail: " + TRANSFORM(lnbytesavail)+CHR(13)+CHR(10),'teste.txt',1)
   STRTOFILE("lnApparentSize: " + TRANSFORM(lnapparentsize)+CHR(13)+CHR(10),'teste.txt',1)

   STRTOFILE("lnSize: " + TRANSFORM(lnsize)+CHR(13)+CHR(10),'teste.txt',1)
   STRTOFILE("lcStatus: " + TRANSFORM(lcstatus)+CHR(13)+CHR(10),'teste.txt',1)

   STRTOFILE("lhInternetSession: " + TRANSFORM(lhinternetsession)+CHR(13)+CHR(10),'teste.txt',1)
   STRTOFILE("lhUrlFile: " + TRANSFORM(lhurlfile)+CHR(13)+CHR(10),'teste.txt',1)

   STRTOFILE("lhConnect: " + TRANSFORM(lhconnect)+CHR(13)+CHR(10)+CHR(13)+CHR(10),'teste.txt',1)
ENDPROC

É o máximo que posso te ajudar, até o momento.
Talvez algum outro colega tenha uma resposta mais clara.

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Ver o tópico anterior Ver o tópico seguinte Voltar ao Topo


 
Permissão deste fórum:
Você não pode responder aos tópicos neste fórum