Clique abaixo para nos ajudar
Conectar-se

Esqueci minha senha

Estamos no Facebook
Buscar
 
 

Resultados por:
 


Rechercher Busca avançada

Quem está conectado
26 usuários online :: 1 usuário cadastrado, Nenhum Invisível e 25 Visitantes :: 1 Motor de busca

paulo2015vfpti

[ Ver toda a lista ]


O recorde de usuários online foi de 468 em 1/3/2012, 10:43
TRY BEGIN E FLOCK()

17/4/2017, 10:32 por AJC

Pessoal estou tendo alguns problemas de gravação em rede, estou usando
try begin, mas vi algo na …

Comentários: 0

Exportar Dados Campo Memo Tabela DBF

10/4/2017, 10:28 por fcampos

Olá bom dia.

Estou tentando exportar os dados de algumas tabelas em formato dbf pelo foxpro.
O …

Comentários: 2

Função EVL()

8/4/2017, 12:18 por Clebervfp

Bom dia a todos.
Vim compartilhar de uma Função do próprio VFP que me benefício muito.
Função …

Comentários: 0

COMO BLOQUEAR REGISTRO OU TABELA NO VISUAL FOXPRO PARA GRAVAÇÃO EM REDE

3/4/2017, 10:29 por AJC

Pessoal estou tendo um problema que acontece sempre busco na minha tabela de clientes o ultimo …

Comentários: 2

Controlar Scanner Twain

31/3/2017, 17:31 por Kleber R Bento

Estou usando o EZTW32.DLL para criar uma ferramenta que escaneia e gera PDF. Porém com esses …

Comentários: 0

Estatísticas
Temos 7079 usuários registrados
O último usuário registrado atende pelo nome de albsilva

Os nossos membros postaram um total de 48 mensagens em 25 assuntos

Outlook x VFP

Ver o tópico anterior Ver o tópico seguinte Ir em baixo

Anexo Outlook x VFP

Mensagem por Marcos Guedes em 5/10/2009, 15:57

Como utilizar:
Código:
LOCAL obj AS OBJECT
m.obj = NEWOBJECT("outlook_auto")
m.obj.setassunto("Automação do Outlook pelo VFP")
m.obj.setdestinatario("destinatario@dominio.com.br")
m.obj.setcopia("copia@dominio.com")
m.obj.setcopiaoculta("copia@oculta.com")
m.obj.setmensagem("Exemplo encontrado no <a href='http://forum.programacaobrasil.com'>Programação Brasil</a><br/><b>Autor</b>: Marcos Guedes")
IF !m.obj.enviarmensagem() THEN
   ?
   ?"Erro: " + m.obj.getmensagemerro()
ELSE
   ?"Email enviado com sucesso!"
ENDIF
m.obj = NULL
Segue a classe responsável pela automação:
Código:
DEFINE CLASS outlook_auto AS CUSTOM

   HIDDEN objoutlook AS "Outlook.Application"
   HIDDEN objmsg AS OBJECT

   HIDDEN cassunto AS STRING
   HIDDEN cdestinatario AS STRING
   HIDDEN ccopia AS STRING
   HIDDEN ccopiaoculta AS STRING
   HIDDEN cmensagem AS STRING

   *!* Mensagem de erro, se houver algum
   HIDDEN mensagemerro AS STRING

   PROCEDURE setassunto AS void
      LPARAMETERS cassunto AS STRING
      *!* Define o assunto com o qual
      *!* o email será enviado
      THIS.cassunto = m.cassunto
   ENDPROC

   PROCEDURE setdestinatario AS void
      LPARAMETERS cdestinatario AS STRING
      *!* Destinatário que deverá receber
      *!* o email a ser enviado
      THIS.cdestinatario = m.cdestinatario
   ENDPROC

   PROCEDURE setcopia AS void
      LPARAMETERS ccopia AS STRING
      *!* Endereço o qual poderá receber uma cópia do email.
      *!* Obs: Será visualizado pelos outros destinatários.
      THIS.ccopia = m.ccopia
   ENDPROC

   PROCEDURE setcopiaoculta AS void
      LPARAMETERS ccopiaoculta AS STRING
      *!* Endereço o qual poderá receber uma cópia do email.
      *!* Obs: Esta cópia não será visualizada pelos demais destinatários
      THIS.ccopiaoculta = m.ccopiaoculta
   ENDPROC

   PROCEDURE setmensagem AS void
      LPARAMETERS mensagem AS STRING
      *!* Conteúdo que será enviado
      *!* Obs: Poderá ser em HTML
      THIS.cmensagem = m.mensagem
   ENDPROC

   PROCEDURE adicionararquivos AS void
      LPARAMETERS ccaminhoarquivo AS STRING
      *!* Adiciona anexos ao email.
      *!* Obs: Esta função poderá ser chamada várias vezes.
      THIS.objmsg.attachments.ADD(m.ccaminhoarquivo)
   ENDPROC

   FUNCTION enviarmensagem AS logical
      LOCAL enviado AS logical
      m.enviado = .F.

      IF EMPTY(THIS.cassunto) THEN
         THIS.mensagemerro = "Assunto não informado!"
         RETURN .F.
      ENDIF

      IF EMPTY(THIS.cdestinatario) THEN
         THIS.mensagemerro = "Email do destinatário não informado!"
         RETURN .F.
      ENDIF

      IF EMPTY(THIS.cmensagem) THEN
         THIS.mensagemerro = "Mensagem não informada!"
         RETURN .F.
      ENDIF

      TRY
         WITH THIS.objmsg
            .subject = THIS.cassunto
            .TO = THIS.cdestinatario
            .cc = THIS.ccopia
            .bcc = THIS.ccopiaoculta

            *!* Mensagem que será enviada, mais a assinatura.
            .htmlbody = THIS.cmensagem + THIS.objmsg.htmlbody
            *!* Envia a mensagem.
            .SEND()
         ENDWITH

         m.enviado = .T.
         THIS.mensagemerro = ""
      CATCH TO oerro
         m.enviado = .F.
         THIS.mensagemerro = m.oerro.MESSAGE
      FINALLY

      ENDTRY
      RETURN m.enviado
   ENDFUNC

   FUNCTION getmensagemerro AS STRING
      *!* Retorna uma possível mensagem de erro, de uma operação.
      RETURN THIS.mensagemerro
   ENDFUNC

   HIDDEN PROCEDURE INIT AS void
      *!* Objetos responsáveis pelo funcionamento da automação
      THIS.objoutlook = CREATEOBJECT("Outlook.Application")
      THIS.objmsg = THIS.objoutlook.createitem(0)

      *!* Valor padrão para algumas variáveis
      THIS.cassunto = ""
      THIS.cdestinatario = ""
      THIS.ccopia = ""
      THIS.ccopiaoculta = ""
      THIS.cmensagem = ""
      THIS.mensagemerro = ""
   ENDPROC

   HIDDEN PROCEDURE DESTROY AS void
      *!* Destrói os objetos responsáveis
      *!* pelo funcionamento da automação
      THIS.objoutlook = NULL
      THIS.objmsg = NULL
   ENDPROC

ENDDEFINE

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por amaury em 16/8/2010, 11:22

bom dia Marcos, tudo em ordem ?
Voce teria alguma rotina para ler as msgs do outlook e salvar por exemplo em uma base de dados em sql ou mysql, to te pedindo este auxilio pq quero salvar as minhas em banco de dados, tenho msgs dese 1999 e gostaria de diminuir o meu arquivo do outlook e não gostaria de perder este historico.

fico no aguardo

Amaury

amaury
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por Marcos Guedes em 16/8/2010, 13:56

Darei uma pesquisadas e qualquer coisa, posto a solução aqui.
Se eu demorar a retornar, pode cobrar.


Se outro colega já tiver a solução, melhor ainda.
Smile

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por hugo em 16/8/2010, 14:09

reputado marcos

_________________
"A tristeza é a falta de alegria, mais sem ela eu não poderia entender a alegria do fato de que a felicidade existe!"
Helio Leites - [Você precisa estar registrado e conectado para ver este link.]
avatar
hugo
Usuário 5 Estrelas
Usuário 5 Estrelas


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por m@r<3|o em 17/8/2010, 00:01

Amauri , voce tem um arquivo dbx , converta da uma olhada em ABC Amber DBX

Abs
Marcelo Fazan

m@r<3|o
Participante Assíduo
Participante Assíduo


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por hugo em 17/8/2010, 08:28

marcelo, entendi bem, tipo, este ABC Amber DBX ele converte o dbx da caixa de entrada o outlook para uma outra extensao e de forma que posso armazenar com seguranca?

eh isto?

_________________
"A tristeza é a falta de alegria, mais sem ela eu não poderia entender a alegria do fato de que a felicidade existe!"
Helio Leites - [Você precisa estar registrado e conectado para ver este link.]
avatar
hugo
Usuário 5 Estrelas
Usuário 5 Estrelas


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por m@r<3|o em 17/8/2010, 10:36

para DBF Access TXT CSV

m@r<3|o
Participante Assíduo
Participante Assíduo


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por Marcos Guedes em 17/8/2010, 11:05

marcelofazan escreveu:Amauri , voce tem um arquivo dbx , converta da uma olhada em ABC Amber DBX

Abs
Marcelo Fazan
Onde está localizado este arquivo .dbx, Marcelo?

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por m@r<3|o em 17/8/2010, 15:45

Para compactar e fazer o backup de pastas de email
""" Voce precisa criar o DBX"""
acho que ele nao existe ou mesmo no localizar nao encontra por ser talves dentro de pasta oculta

Selecione uma pasta de email.
No menu Arquivo, aponte para Pasta e clique em Compactar.
Para fazer o backup da pasta, localize o arquivo da pasta e copie-o para uma pasta de backup, para um disquete ou para uma unidade de rede. As pastas de email do Outlook Express possuem a extensão .dbx (por exemplo, "Itens Enviados.dbx").

Entao :
1 - Gerar o Backup fazendo """ no outlook menu Arquivo, aponte para Pasta e clique em Compactar. """


e depois ir em :

2- Outlook - Ferramentas - Opcoes nova janela - Manutencao e tem um botao pasta de armazenamento
ai la tem o caminho de onde salva o bakcup aparece ....
C:\Documents and Settings\USMICRO\Configurações locais\Dados de aplicativos\Identities\{4D087487-8980-C9747B28D95D}\Microsoft\Outlook Express

é o caminho onde salva o backup

é por aii ... .

Depois usar a ferramentinha , quem sabe os DBX viram DBF

Abs
Marcelo Fazan

m@r<3|o
Participante Assíduo
Participante Assíduo


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por hugo em 17/8/2010, 19:32

Vou deixar este post marcado, vira e mexe tenho problemas com clientes
por causa do lixao do outlook

valeu marcelo

_________________
"A tristeza é a falta de alegria, mais sem ela eu não poderia entender a alegria do fato de que a felicidade existe!"
Helio Leites - [Você precisa estar registrado e conectado para ver este link.]
avatar
hugo
Usuário 5 Estrelas
Usuário 5 Estrelas


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por wms em 27/8/2010, 08:34

Marcos,

Você sabe se tem como colocar uma imagem no corpo do texto ao invés de um texto propriamente dito?
Só para você entender melhor, se ao invés de enviar um texto no corpo eu quisesse enviar uma newsletter que esta no formato JPG, tem como?

Abraços.
avatar
wms
Participante Regular
Participante Regular


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por Marcos Guedes em 27/8/2010, 10:18

Uma das formas que tenho certeza que funciona é enviando em formato HTML.
O src da imagem poderá ser a url onde sua imagem estiver hospedada.

Mas se a imagem for do PC, então tenho que pesquisar uma forma.

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por Julio em 27/8/2010, 16:46

Marcelo Fazan Escreveu
C:\Documents and Settings\USMICRO\Configurações locais\Dados de aplicativos\Identities\{4D087487-8980-C9747B28D95D}\Microsoft\Outlook Express

A parte que esta entre "{}" chaves acho que muda de micro para micro e deve ser habilitado o modo de exibição de pastas ocultas.

Julio
Usuário 5 Estrelas
Usuário 5 Estrelas


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por hugo em 28/8/2010, 12:02

lembrando que usmicro vai variar pois isto ai eh o nome do usuario

_________________
"A tristeza é a falta de alegria, mais sem ela eu não poderia entender a alegria do fato de que a felicidade existe!"
Helio Leites - [Você precisa estar registrado e conectado para ver este link.]
avatar
hugo
Usuário 5 Estrelas
Usuário 5 Estrelas


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por Marcos Guedes em 28/8/2010, 14:57

Simples de obter a partir do VFP.

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por coconaithy em 11/7/2011, 10:26

Marcos, bom dia.
Esta Rotina é muito boa e resolve um probelma de envia e-mail automatico.
só que estou com um problema, no projeto funciona normalmente no excultavel não, na hora do envio abre uma tela do outlook pedindo confirmação informando que um "programa esta tentando acessar emaisl amarzenado no outlook, deseja perimitr isso?"

coconaithy
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por Marcos Guedes em 11/7/2011, 13:23

Teste em outras máquinas e estude o código.
Talvez seja necessário mais um comando para esconder a notificação.

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por coconaithy em 11/7/2011, 15:11

Marcos, obrigado.
Realmente testei em outro micro e deu certo.
ainda sou novo com VFP, estou aprendento aos poucos.

coconaithy
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por coconaithy em 11/7/2011, 15:28

Marcos, uma duvida.
o versão do office 2003 para 2007 tem diferença?

coconaithy
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por coconaithy em 11/7/2011, 16:23

Resolvido.

instalei o office 2007.

coconaithy
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Anexo Re: Outlook x VFP

Mensagem por Conteúdo patrocinado


Conteúdo patrocinado


Voltar ao Topo Ir em baixo

Ver o tópico anterior Ver o tópico seguinte Voltar ao Topo


 
Permissão deste fórum:
Você não pode responder aos tópicos neste fórum