Clique abaixo para nos ajudar
Login

Esqueci minha senha

Estamos no Facebook
Buscar
 
 

Resultados por:
 


Rechercher Busca avançada

Quem está conectado
5 usuários online :: Nenhum usuário registrado, Nenhum Invisível e 5 Visitantes :: 2 Motores de busca

Nenhum

[ Ver toda a lista ]


O recorde de usuários online foi de 468 em 1/3/2012, 10:43
Últimos assuntos
USAR REPORT FORM

30/12/2016, 09:06 por AJC

Pessoal bom dia,
Estou com um grande problema, já pesquisei muita coisa sobre report form, mas o …

Comentários: 3

Impressora Ticket

15/11/2016, 09:20 por clima238

Bom dia,
Por favor alguém me explique porque o código abaixo imprime no ecrã em vez do printer: …

Comentários: 2

Visite meu canal no Youtube

20/1/2017, 00:45 por ImRicoh

VFP Unlimited


Comentários: 0

Bloquear edição do ListBox

17/6/2010, 15:13 por Julio

Pessoal

Boa Tarde!

Tnho uma listbox apenas para exibir o resultado.
Preciso bloquear a listbox …

Comentários: 17

automação do mozilla e chrome

15/1/2017, 12:16 por Handerson Mildroz

Boa tarde a todos!

Sou iniciante no VFP. Preciso de ajuda, pois tenho um código que usa o …

Comentários: 0

Estatísticas
Temos 6991 usuários registrados
O último usuário registrado atende pelo nome de cpmacedo

Os nossos membros postaram um total de 9 mensagens em 3 assuntos

Como enviar e-mails do VFP

Ver o tópico anterior Ver o tópico seguinte Ir em baixo

Resolvido Como enviar e-mails do VFP

Mensagem por rdyma em 28/9/2015, 08:29

Srs,

Preciso enviar boletos via e-mail e não sei como fazê-lo, usando o VFP.

É um boleto para cada destinatário diferente.
O mesmo, como se trata de boleto, obedeceria um formulário padrão.
Imaginei em desenhar o boleto em html, gerando um formulário padrão, para poder somente envia-los.
Mas como ?

Alguém pode me ajudar ?

rdyma
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Resolvido Re: Como enviar e-mails do VFP

Mensagem por Marcos Guedes em 28/9/2015, 08:52

Rdyma,
Dá uma pesquisada no fórum pois temos algumas rotinas de envio de email.
Você poderia criar o HTML ou enviá-lo como anexo.

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Resolvido Re: Como enviar e-mails do VFP

Mensagem por rdyma em 28/9/2015, 22:22

Marcos,

Muito Obrigado.

Vou pesquisar. Very Happy

rdyma
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Resolvido Re: Como enviar e-mails do VFP

Mensagem por coconaithy em 14/1/2016, 13:40

Ola,

eu utilizo desta forma, deste que o Outlook esteja aberto, faço desta forma, pois onde trabalho a configuração tem que ser via EXCHANGE

SET PROCEDURE TO emailauto.prg additive
LOCAL obj AS OBJECT
m.obj = NEWOBJECT("outlook_auto")
m.obj.setassunto("assunto do e-mail")
m.obj.setdestinatario("teste@teste.com")
m.obj.setcopia("teste@teste.com")
m.obj.setcopiaoculta("")
m.obj.adicionararquivos("")
m.obj.setmensagem("teste de envio"+"</a><br/><b></b> </a><br/><b></b> ")
IF !m.obj.enviarmensagem() THEN
  ?
  ?"Erro: " + m.obj.getmensagemerro()
ELSE
  ?"Email enviado com sucesso!"
ENDIF
m.obj = NULL
endif

o comando abaixo é referente ao codigo do arquivo emailauto.prg

DEFINE CLASS outlook_auto AS CUSTOM

  HIDDEN objoutlook AS "Outlook.Application"
  HIDDEN objmsg AS OBJECT

  HIDDEN cassunto AS STRING
  HIDDEN cdestinatario AS STRING
  HIDDEN ccopia AS STRING
  HIDDEN ccopiaoculta AS STRING
  HIDDEN cmensagem AS STRING

  *!* Mensagem de erro, se houver algum
  HIDDEN mensagemerro AS STRING

  PROCEDURE setassunto AS void
     LPARAMETERS cassunto AS STRING
     *!* Define o assunto com o qual
     *!* o email será enviado
     THIS.cassunto = m.cassunto
  ENDPROC

  PROCEDURE setdestinatario AS void
     LPARAMETERS cdestinatario AS STRING
     *!* Destinatário que deverá receber
     *!* o email a ser enviado
     THIS.cdestinatario = m.cdestinatario
  ENDPROC

  PROCEDURE setcopia AS void
     LPARAMETERS ccopia AS STRING
     *!* Endereço o qual poderá receber uma cópia do email.
     *!* Obs: Será visualizado pelos outros destinatários.
    THIS.ccopia = m.ccopia
  ENDPROC

  PROCEDURE setcopiaoculta AS void
     LPARAMETERS ccopiaoculta AS STRING
     *!* Endereço o qual poderá receber uma cópia do email.
     *!* Obs: Esta cópia não será visualizada pelos demais destinatários
     THIS.ccopiaoculta = m.ccopiaoculta
  ENDPROC

  PROCEDURE setmensagem AS void
     LPARAMETERS mensagem AS STRING
     *!* Conteúdo que será enviado
     *!* Obs: Poderá ser em HTML
     THIS.cmensagem = m.mensagem
  ENDPROC

  PROCEDURE adicionararquivos AS void
     LPARAMETERS ccaminhoarquivo AS STRING
     *!* Adiciona anexos ao email.
     *!* Obs: Esta função poderá ser chamada várias vezes.
     THIS.objmsg.attachments.ADD(m.ccaminhoarquivo)
  ENDPROC

  FUNCTION enviarmensagem AS logical
     LOCAL enviado AS logical
     m.enviado = .F.

     IF EMPTY(THIS.cassunto) THEN
        THIS.mensagemerro = "Assunto não informado!"
        RETURN .F.
     ENDIF

     IF EMPTY(THIS.cdestinatario) THEN
        THIS.mensagemerro = "Email do destinatário não informado!"
        RETURN .F.
     ENDIF

     IF EMPTY(THIS.cmensagem) THEN
        THIS.mensagemerro = "Mensagem não informada!"
        RETURN .F.
     ENDIF

     TRY
        WITH THIS.objmsg
           .subject = THIS.cassunto
           .TO = THIS.cdestinatario
           .cc = THIS.ccopia
           .bcc = THIS.ccopiaoculta

           *!* Mensagem que será enviada, mais a assinatura.
           .htmlbody = THIS.cmensagem + THIS.objmsg.htmlbody
           *!* Envia a mensagem.
           .SEND()
        ENDWITH

        m.enviado = .T.
        THIS.mensagemerro = ""
     CATCH TO oerro
        m.enviado = .F.
        THIS.mensagemerro = m.oerro.MESSAGE
     FINALLY

     ENDTRY
     RETURN m.enviado
  ENDFUNC

  FUNCTION getmensagemerro AS STRING
     *!* Retorna uma possível mensagem de erro, de uma operação.
     RETURN THIS.mensagemerro
  ENDFUNC

  HIDDEN PROCEDURE INIT AS void
     *!* Objetos responsáveis pelo funcionamento da automação
     THIS.objoutlook = CREATEOBJECT("Outlook.Application")
     THIS.objmsg = THIS.objoutlook.createitem(0)

     *!* Valor padrão para algumas variáveis
     THIS.cassunto = ""
     THIS.cdestinatario = ""
     THIS.ccopia = ""
     THIS.ccopiaoculta = ""
     THIS.cmensagem = ""
     THIS.mensagemerro = ""
  ENDPROC

  HIDDEN PROCEDURE DESTROY AS void
     *!* Destrói os objetos responsáveis
     *!* pelo funcionamento da automação
     THIS.objoutlook = NULL
     THIS.objmsg = NULL
  ENDPROC

ENDDEFINE
*__

coconaithy
Começando a Participar
Começando a Participar


Voltar ao Topo Ir em baixo

Ver o tópico anterior Ver o tópico seguinte Voltar ao Topo


 
Permissão deste fórum:
Você não pode responder aos tópicos neste fórum