Clique abaixo para nos ajudar
Login

Esqueci minha senha

Estamos no Facebook
Buscar
 
 

Resultados por:
 


Rechercher Busca avançada

Quem está conectado
12 usuários online :: Nenhum usuário registrado, Nenhum Invisível e 12 Visitantes :: 2 Motores de busca

Nenhum

[ Ver toda a lista ]


O recorde de usuários online foi de 468 em 1/3/2012, 10:43
Como preencher campos vazios

9/2/2017, 11:55 por Linghston

Pessoal boa tarde,

É o seguinte, eu preciso preencher os campos de uma coluna da tabela DBF que …

Comentários: 2

Enviar msg para WhatsAPP via VFP

7/2/2017, 10:31 por Eliana

Olá Pessoal!

Alguém sabe se é possível enviar mensagem para o WhatsAPP via VFP?


Grata


Comentários: 0

Tudo dá errado

3/2/2017, 16:50 por Douglas Pascini

Troquei de maquina, achei que seria uma boa, [Você precisa estar registrado e conectado para ver esta imagem.]  pois passei para uma maquina melhor.

Instalei o …

Comentários: 1

URGENTE - Instalação do aplicativo

24/1/2017, 08:51 por Douglas Pascini

Bom dia. Estou com um problema, ao fazer a instalação (colocar os arquivo) do aplicativo na …

Comentários: 0

USAR REPORT FORM

30/12/2016, 09:06 por AJC

Pessoal bom dia,
Estou com um grande problema, já pesquisei muita coisa sobre report form, mas o …

Comentários: 3

Estatísticas
Temos 7021 usuários registrados
O último usuário registrado atende pelo nome de diegopeixoto

Os nossos membros postaram um total de 21 mensagens em 12 assuntos

Biblioteca de códigos fontes

Ver o tópico anterior Ver o tópico seguinte Ir em baixo

Anexo Biblioteca de códigos fontes

Mensagem por Marcos Guedes em 6/8/2009, 14:09

Olá pessoal!
Pesquisando na net acabei encontrando este código que nos dá acesso a uma biblioteca de soluções através da API do windows.
Crie um PRG, cole o código abaixo e execute.
Código:
PUBLIC objForm
objForm = CreateObject("Tform")
objForm.Visible = .T.
* end of main
 
DEFINE CLASS Tform As Form
#DEFINE ccBaseAddr "http://www.news2news.com/vfp/"
#DEFINE ccCgiAddr  "http://www.news2news.com/cgi-bin/w32query.php?quser=guest&"
    Caption=" VFP code samples on " + ccBaseAddr
    Width=760
    Height=500
    Autocenter=.T.
    ShowTips=.T.
    csList="cs" + SUBSTR(SYS(2015),3,10)
 
    ADD OBJECT pframe As Tframe WITH Left=6, Top=5, Width=748, Height=440
    ADD OBJECT lblUrl As Label WITH Left=12, Top=460, Autosize=.T.,;
        ForeColor=Rgb(0,0,192), FontUnderline=.T.,;
        TooltipText="Click to open"
 
PROCEDURE Init
    DECLARE INTEGER ShellExecute IN shell32;
        INTEGER, STRING, STRING, STRING, STRING, INTEGER
    DECLARE INTEGER URLDownloadToCacheFile IN urlmon;
        INTEGER lpUnkcaller, STRING szURL, STRING @szFileName,;
        INTEGER dwBufLength, INTEGER dwReserved, INTEGER pBSC
    THIS.pframe.Resize
    THIS.PopulateList
 
PROCEDURE Destroy
    THIS.pframe.pgList.lst.RowsourceType = 0
    IF USED(THIS.csList)
        USE IN (THIS.csList)
    ENDIF
 
procedure resize
* Thanks Bruce :)
    with this
        stor .Width - 12 to .pframe.Width
        stor .Height - 60 to .pframe.Height   
        stor .Height - 40 to .lblUrl.Top
    endWith
 
PROCEDURE pframe.pgList.lst.InteractiveChange
    ThisForm.lblUrl.Caption = ThisForm.GetUrl()
 
PROCEDURE lblUrl.MouseDown
LPARAMETERS nButton, nShift, nXCoord, nYCoord
    = ShellExecute(0, "open", ThisForm.GetUrl(), "", "", 3)
 
PROCEDURE pframe.pgExample.Activate
    ThisForm.DisplayExample
 
PROCEDURE pframe.pglist.lst.DblClick
    ThisForm.pframe.ActivePage = 2
 
FUNCTION GetUrl
RETURN ccBaseAddr + "?example=" + ALLT(THIS.pframe.pgList.lst.Value)
 
PROCEDURE PopulateList
    LOCAL cRequest, cTargetFile
    cRequest = ccCgiAddr + "qtarget=examples&qmode=list"
    cTargetFile = THIS.RemoteToLocal(cRequest)
 
    IF Not EMPTY(cTargetFile)
        CREATE CURSOR (THIS.csList) (id N(5), name C(200))
        APPEND FROM (cTargetFile) TYPE DELIM WITH ,
        WITH THIS.pframe.pgList.lst
            .RowsourceType = 2
            .Rowsource = THIS.csList
            .ColumnWidths="40,500"
            IF .listCount > 0
                .listIndex = 1
            ENDIF
            .InteractiveChange
        ENDWITH
    ENDIF
 
PROCEDURE DisplayExample
    LOCAL cRequest, cTargetFile
    cRequest = ccCgiAddr + "qtarget=examples&qmode=source&qindex=" +;
        ALLTRIM(ThisForm.pframe.pgList.lst.Value)
    cTargetFile = THIS.RemoteToLocal(cRequest)
 
    IF Not EMPTY(cTargetFile)
        WITH ThisForm.pframe.pgExample.txtSource
            .Value = FILETOSTR(cTargetFile)
            .Refresh
        ENDWITH
    ENDIF
 
FUNCTION RemoteToLocal(cRequest)
    LOCAL nResult, cTargetFile
    cTargetFile = Repli(Chr(0), 250)
    WAIT WINDOW NOWAIT "Downloading remote file..."
    nResult = URLDownloadToCacheFile(0, cRequest, @cTargetFile,;
        Len(cTargetFile), 0,0)
    WAIT CLEAR
    DOEVENTS
RETURN STRTRAN(cTargetFile, Chr(0), "")
ENDDEFINE
 
DEFINE CLASS Tframe As PageFrame
    ADD OBJECT pgList As TpageList WITH Caption="List of examples"
    ADD OBJECT pgExample As TpageExample WITH Caption="Source Code"
 
PROCEDURE Resize
    WITH THIS.pgList
        .lst.Width = THIS.Width - 14
        .lst.Height = THIS.height - .lst.Top - 50
    ENDWITH
    WITH THIS.pgExample
        .txtSource.Width = THIS.Width - 14
        .txtSource.Height = THIS.height - .txtSource.Top - 50
    ENDWITH
ENDDEFINE
 
DEFINE CLASS TpageList As Page  && Page object
    ADD OBJECT lst As ListBox WITH Left=5, Top=5, FontName="Arial",;
        FontSize=10, ColumnCount=2, BoundColumn=1
ENDDEFINE
 
DEFINE CLASS TpageExample As Page  && Page object
    ADD OBJECT txtSource As EditBox WITH Left=5, Top=5,;
        FontName="Courier New", FontSize=9, ForeColor = RGB(0,96,128)
ENDDEFINE

Obs: É necessário estar conectado à internet!
Fonte: [Você precisa estar registrado e conectado para ver este link.]

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Biblioteca de códigos fontes

Mensagem por mfelis em 7/8/2009, 09:23

e uma boa ideiá que pena que a senha ou usuario estão errados

mfelis
Participa Bastante
Participa Bastante


Voltar ao Topo Ir em baixo

Anexo Re: Biblioteca de códigos fontes

Mensagem por Fernando Milanez em 7/8/2009, 09:55

Também não consegui acessar,

Código:
-1. Invalid user name and/or password.

* * *
Find and change the following line in the form's code:

#DEFINE ccCgiAddr 'http://news2news.com/cgi-bin/w32query.php?quser=<user name>&qpwd=<password>&'

Substitute <user name> and <password> parts with user name and password that you were given upon start of your membership.

* * *
If you still have not registered your membership, you can do it at
http://news2news.com/vfp/?generic=Project#membership

* * *
Copyright (c) 2001-2004 News2News, Inc.
Email: [Você precisa estar registrado e conectado para ver este link.]

Fernando Milanez
Participante Regular
Participante Regular


Voltar ao Topo Ir em baixo

Anexo Re: Biblioteca de códigos fontes

Mensagem por Marcos Guedes em 7/8/2009, 10:06

Este erro realmente ocorre, mas clique no link onde é demonstrado na figura, que você será levado à página referente ao código.
[Você precisa estar registrado e conectado para ver esta imagem.]

_________________
Marcos Guedes - Programador e desenvolvedor Web.


Visite o nosso portal:
[Você precisa estar registrado e conectado para ver este link.]

Marcos Guedes
Webmaster
Webmaster


Voltar ao Topo Ir em baixo

Anexo Re: Biblioteca de códigos fontes

Mensagem por mfelis em 7/8/2009, 10:12

ok

mfelis
Participa Bastante
Participa Bastante


Voltar ao Topo Ir em baixo

Anexo Re: Biblioteca de códigos fontes

Mensagem por Fernando Milanez em 7/8/2009, 11:11

Realmente, rs Very Happy

Fernando Milanez
Participante Regular
Participante Regular


Voltar ao Topo Ir em baixo

Ver o tópico anterior Ver o tópico seguinte Voltar ao Topo


 
Permissão deste fórum:
Você não pode responder aos tópicos neste fórum