Clique abaixo para nos ajudar
Conectar-se

Esqueci minha senha

Estamos no Facebook
Buscar
 
 

Resultados por:
 


Rechercher Busca avançada

Quem está conectado
28 usuários online :: Nenhum usuário registrado, Nenhum Invisível e 28 Visitantes :: 2 Motores de busca

Nenhum

[ Ver toda a lista ]


O recorde de usuários online foi de 468 em 1/3/2012, 10:43
TRY BEGIN E FLOCK()

17/4/2017, 10:32 por AJC

Pessoal estou tendo alguns problemas de gravação em rede, estou usando
try begin, mas vi algo na …

Comentários: 0

Exportar Dados Campo Memo Tabela DBF

10/4/2017, 10:28 por fcampos

Olá bom dia.

Estou tentando exportar os dados de algumas tabelas em formato dbf pelo foxpro.
O …

Comentários: 2

Função EVL()

8/4/2017, 12:18 por Clebervfp

Bom dia a todos.
Vim compartilhar de uma Função do próprio VFP que me benefício muito.
Função …

Comentários: 0

COMO BLOQUEAR REGISTRO OU TABELA NO VISUAL FOXPRO PARA GRAVAÇÃO EM REDE

3/4/2017, 10:29 por AJC

Pessoal estou tendo um problema que acontece sempre busco na minha tabela de clientes o ultimo …

Comentários: 2

Controlar Scanner Twain

31/3/2017, 17:31 por Kleber R Bento

Estou usando o EZTW32.DLL para criar uma ferramenta que escaneia e gera PDF. Porém com esses …

Comentários: 0

Estatísticas
Temos 7064 usuários registrados
O último usuário registrado atende pelo nome de Rpedrozo

Os nossos membros postaram um total de 48 mensagens em 25 assuntos

Editar um memo no cursor

Ver o tópico anterior Ver o tópico seguinte Ir em baixo

Editar um memo no cursor

Mensagem por Queliton Pires em 17/12/2014, 13:33

Olá, pessoal !

estou com o seguinte problema.

estou precisando converter uma telas que tem algumas classes que eram vcx e agora viram prg.

estou fazendo uma classe, que monta uma string pra mim, como esta no código a baixo
Código:
   
procedure FOL_TrocaClassesPrgs
      _cliptext = ""

      dimension voa_telas(1)
      adir(voa_telas, sys(5)+sys(2003)+'\MY-APPS\LIBRARIES\*.scx')
      for v = 1 to alen(voa_telas, 1)

         use (voa_telas[v, 1]) exclusive alias tela
         select tela

         for x = 1 to alen(this.VOA_Classes)
            locate for this.VOA_Classes[x] $ alltrim(tela.class)
            if found()
               _cliptext = _cliptext + 'VGO_Gen.Fol_newobject(this, '  + '"' + alltrim(tela.objname) + '", ' + '"' +  alltrim(tela.class) + '", ' + '"' + alltrim(juststem(tela.classloc)) + '.prg") ' + chr(10) + chr(13)
               *-delete in tela
               *-pack
            endif
         endfor

         use in tela
         compile form (voa_telas[v, 1])
      endfor

      *-modify  form (plc_tela +".scx")
   endproc

gostaria de inserir essa string, dento do init da minha tela que está aberta como cursor no momento.

desde já agradeço a ajuda.

Queliton Pires
Participa Pouco
Participa Pouco


Voltar ao Topo Ir em baixo

Re: Editar um memo no cursor

Mensagem por Queliton Pires em 22/12/2014, 15:23

Consegui resolver.

segue todo o código da classe abaixo

Código:

public vgo_querys as object

vgo_querys = createobject("CGO_ChangeClass")

define class CGO_ChangeClass as custom

   dimension VOA_Classes(27)
   dimension VOA_ProgVcx(8)
   dimension VOA_Telas(1)

   procedure init

      set datasession to 1

      if !('\MY-APPS\LIBRARIES' $ set("Path"))
         set path to sys(5)+sys(2003)+'\MY-APPS\LIBRARIES' additive
      endif

      this.FOL_InitArrays()
   endproc

   procedure FOL_ChangeClassAllForms
      local VLC_String, VLL_Replace
      set datasession to 1

      VLC_String = ""

      adir(this.VOA_Telas, sys(5)+sys(2003)+'\MY-APPS\LIBRARIES\*.scx')

      for y = 1 to alen(this.VOA_Telas, 1)
         use (this.VOA_Telas[y, 1]) exclusive alias TELA
         select TELA

         if used("TELA")
            VLC_String = this.FOC_CreateString()

            if vartype(VLC_String) = "C" and !empty(VLC_String)
               VLL_Replace= .t.
            else
               VLL_Replace= .f.
            endif
         endif

         if VLL_Replace
            this.FOL_ChangeMemo(VLC_String)
         endif

         use in TELA

         if VLL_Replace
            compile form (this.VOA_Telas[y, 1])
         endif
      endfor
   endproc


   procedure FOC_CreateLineClassForm
      lparameters PLC_Tela
      PLC_Tela = alltrim(PLC_Tela)
      _cliptext = ""

      use (PLC_Tela +".scx") exclusive alias TELA
      select TELA
      if used("TELA")
         _cliptext = this.FOC_CreateString()
         use in TELA
         compile form (PLC_Tela +".scx")
         modify  form (PLC_Tela +".scx")
      else
         messagebox("Não Encontrou a tela", 0+64, "Informação")
      endif
   endproc

   procedure FOC_CreateLineClassWithMessageErro
      lparameters PLC_Tela

      messagebox("Ainda falta tratar algumas coisa para funcionar", 0+64, "Informação")
      return .t.

      PLC_Tela = alltrim(PLC_Tela)
      _cliptext = ""

      on error do errotelas

      use (PLC_Tela +".scx") exclusive alias TELA

      on error

      locate for  upper(plc_class) $ upper(TELA.objname)
      _cliptext = 'VGO_Gen.Fol_newobject(this, '  + '"'+ alltrim(TELA.objname) + '", ' + '"' +  alltrim(TELA.class) + '", ' + '"' + alltrim(juststem(TELA.classloc)) + '.prg")'

      if upper(plc_class) $ upper(TELA.objname)
         delete in TELA
         pack
      endif
      use in TELA
      compile form (PLC_Tela +".scx")
      modify  form (PLC_Tela +".scx")
   endproc

   procedure errotelas
      ? 'Line of code with error: ' + message(1)
      ? 'Error number: ' + str(error( ))
      ? 'Error message: ' + message( )
   endproc

   procedure FOL_InitArrays
      with this
         *----Classes
         .VOA_Classes[1]  = "cgo_reservetransport"
         .VOA_Classes[2]  = "cgo_movebalanceaccount_l"
         .VOA_Classes[3]  = "cgo_costappropriation"
         .VOA_Classes[4]  = "cgo_accountingintegration_l"
         .VOA_Classes[5]  = "cgo_movecrdbudget_l"
         .VOA_Classes[6]  = "cgo_calcquitacao_l"
         .VOA_Classes[7]  = "cgo_generatefiletxtpayable_l"
         .VOA_Classes[8]  = "cgo_controlapedido_l"
         .VOA_Classes[9]  = "cgo_verifyifhasdebt_l"
         .VOA_Classes[10] = "cgo_transportarateioprojeto_l"
         .VOA_Classes[11] = "cgo_explosao_l"
         .VOA_Classes[12] = "cgo_salesemployees_c"
         .VOA_Classes[13] = "cgo_accumulator_n"
         .VOA_Classes[14] = "cgo_getstocklimits_u"
         .VOA_Classes[15] = "cgo_calckardex_l"
         .VOA_Classes[16] = "cgo_childrenplaces_a"
         .VOA_Classes[17] = "cgo_moveaccumulator_l"
         .VOA_Classes[18] = "cgo_moverasteraccumulator_l"
         .VOA_Classes[19] = "cgo_j08_functions_l"
         .VOA_Classes[20] = "cgo_isvalidliberator_l"
         .VOA_Classes[21] = "cgo_totalquitacaopagar_l"
         .VOA_Classes[22] = "cgo_chkrateio"
         .VOA_Classes[23] = "cgo_chkifopen_l"
         .VOA_Classes[24] = "cgo_transportappropriation_l"
         .VOA_Classes[25] = "cgo_verifybudgetbalance_n"
         .VOA_Classes[26] = "cgo_totalreparcelamentoreceber_l"
         .VOA_Classes[27] = "cgo_j24_functions"

         *--Vcx que viram prgs
         .VOA_ProgVcx[1] = "sgo_j_function"
         .VOA_ProgVcx[2] = "sgo_f_function"
         .VOA_ProgVcx[3] = "sgo_r_function"
         .VOA_ProgVcx[4] = "sgo_b_integrate"
         .VOA_ProgVcx[5] = "sgo_prgbasic"
         .VOA_ProgVcx[6] = "sgo_k_function"
         .VOA_ProgVcx[7] = "sgo_d_function"
         .VOA_ProgVcx[8] = "sgo_e_function"
      endwith
   endproc


   procedure FOC_CreateString
      local VLC_String
      VLC_String = ""

      for x = 1 to alen(this.VOA_Classes)
         select TELA
         locate for this.VOA_Classes[x] $ alltrim(TELA.class)
         if found()
            VLC_String = VLC_String + 'VGO_Gen.Fol_newobject(this, '  + '"' + alltrim(TELA.objname) + '", ' + '"' +  alltrim(TELA.class) + '", ' + '"' + alltrim(juststem(TELA.classloc)) + '.prg") ' + chr(10) + chr(13)
            select TELA
            delete in TELA
            pack
         endif
      endfor

      return VLC_String
   endproc


   procedure FOL_ChangeMemo
      lparameters PLC_StringClass
      local VLC_TrocaMemo, VLC_StringClass, VLC_String

      store "" to VLC_String, VLC_TrocaMemo
      VLC_StringClass = PLC_StringClass

      locate for 'FORM' $ alltrim(upper(TELA.baseclass))
      if found()

         VLC_TrocaMemo = strextract(upper(TELA.methods), 'PROCEDURE INIT', 'ENDPROC', 1, 0)

         if vartype(VLC_TrocaMemo) =  "C" and !empty(VLC_TrocaMemo)
            replace TELA.methods with strtran(upper(TELA.methods), VLC_TrocaMemo, '') in TELA
            VLC_TrocaMemo = 'PROCEDURE Init ' + chr(10) + chr(13) + VLC_TrocaMemo + chr(10) + chr(13) + VLC_StringClass + chr(10) + chr(13) + 'ENDPROC'
            replace TELA.methods with strtran(upper(TELA.methods), 'PROCEDURE INITENDPROC', VLC_TrocaMemo)
         else
            VLC_String = TELA.methods + chr(10) + chr(13) + 'PROCEDURE Init '
            VLC_String = VLC_String   + chr(10) + chr(13) + 'lparameters PLN_FrmType, PLO_Object'
            VLC_String = VLC_String   + chr(10) + chr(13) + VLC_TrocaMemo
            VLC_String = VLC_String   + chr(10) + chr(13) + VLC_StringClass
            VLC_String = VLC_String   + chr(10) + chr(13) + 'dodefault(PLN_FrmType, PLO_Object)'
            VLC_String = VLC_String   + chr(10) + chr(13) + 'ENDPROC'
            replace TELA.methods with VLC_String in TELA
         endif
      endif
   endproc
enddefine


Queliton Pires
Participa Pouco
Participa Pouco


Voltar ao Topo Ir em baixo

Ver o tópico anterior Ver o tópico seguinte Voltar ao Topo


 
Permissão deste fórum:
Você não pode responder aos tópicos neste fórum