CHAT x VFP

[Marcos Guedes]

Criei um CHAT simples utilizando o VFP 9.0 e decidi compartilhar com os colegas.

Abaixo está o link do código fonte do CHAT.
Tentei criá-lo de forma que seja fácil adaptá-lo para algo mais complexo, futuramente:
- Clique aqui para baixar o arquivo!

Espero que gostem!
Qualquer dúvida a respeito, é só postar.

Obs: Conto com a ajuda dos colegas para melhorá-lo!

[Marcos Guedes]

Como utilizar:

- Para rodar na mesma máquina (para teste) basta executar duas instância do arquivo chatpro.exe
- Para torná-lo funcional num em rede, é necessário abrir o arquivo chat.ini e informar o caminho acessível aos usuários que participarão do chat.

Obs: Fiz uns testes local e em rede e funcionou perfeitamente bem!

[Marcos Guedes]

Mais um exemplo para os colegas:

[Você precisa estar registrado e conectado para ver esta imagem.][Você precisa estar registrado e conectado para ver este link.] alt="" />

Código:

PUBLIC oform, oform2

oform = CREATEOBJECT("clsChat",1)
oform.VISIBLE = .T.

oform2 = CREATEOBJECT("clsChat",2)
oform2.VISIBLE = .T.

READ EVENTS

STORE NULL TO oform, oform2
RELEASE oform, oform2

DEFINE CLASS clschat AS FORM

   TOP = 0
   LEFT = 0
   HEIGHT = 268
   WIDTH = 376
   DOCREATE = .T.
   CAPTION = "VFP CHAT"
   NAME = "clschat"

   ADD OBJECT txtchatname AS TEXTBOX WITH ;
      HEIGHT = 23, ;
      LEFT = 216, ;
      TOP = 12, ;
      WIDTH = 132, ;
      NAME = "txtChatname"

   ADD OBJECT edtchat AS EDITBOX WITH ;
      HEIGHT = 134, ;
      LEFT = 24, ;
      READONLY = .T., ;
      TOP = 48, ;
      WIDTH = 324, ;
      DISABLEDBACKCOLOR = RGB(255,255,255), ;
      DISABLEDFORECOLOR = RGB(0,0,0), ;
      NAME = "edtChat"

   ADD OBJECT txtmessage AS TEXTBOX WITH ;
      HEIGHT = 23, ;
      LEFT = 84, ;
      TOP = 194, ;
      WIDTH = 264, ;
      NAME = "txtMessage"

   ADD OBJECT command1 AS COMMANDBUTTON WITH ;
      TOP = 221, ;
      LEFT = 298, ;
      HEIGHT = 25, ;
      WIDTH = 50, ;
      CAPTION = "Send", ;
      NAME = "Command1"

   ADD OBJECT winsock1 AS wscontrol

   ADD OBJECT label2 AS LABEL WITH ;
      AUTOSIZE = .T., ;
      BACKSTYLE = 0, ;
      CAPTION = "MESSAGE", ;
      HEIGHT = 17, ;
      LEFT = 24, ;
      TOP = 197, ;
      WIDTH = 59, ;
      NAME = "Label2"

   ADD OBJECT label1 AS LABEL WITH ;
      AUTOSIZE = .T., ;
      BACKSTYLE = 0, ;
      CAPTION = "CHAT NAME", ;
      HEIGHT = 17, ;
      LEFT = 144, ;
      TOP = 15, ;
      WIDTH = 70, ;
      NAME = "Label1"

   PROCEDURE INIT
      LPARAMETERS plform
      IF plform = 1
         THISFORM.winsock1.OBJECT.BIND(1234)
         THISFORM.txtchatname.VALUE = "likestochat"
      ELSE
         THISFORM.winsock1.OBJECT.BIND(1235)
         THISFORM.txtchatname.VALUE = "sirchatalot"
         THISFORM.AUTOCENTER = .T. &&So they don't overlap
      ENDIF
      THISFORM.txtmessage.SETFOCUS()
   ENDPROC

   PROCEDURE DESTROY
      THISFORM.REMOVEOBJECT('WinSock1')
   ENDPROC

   PROCEDURE UNLOAD
      CLEAR EVENTS
   ENDPROC

   PROCEDURE txtmessage.KEYPRESS
      LPARAMETERS nkeycode, nshiftaltctrl
      IF nkeycode = 13 AND nshiftaltctrl = 0
         IF !EMPTY(THISFORM.txtmessage.VALUE)
            THISFORM.command1.CLICK()
         ENDIF
      ENDIF
   ENDPROC

   PROCEDURE command1.CLICK
      LOCAL schatname, smessagesent
      WITH THISFORM
         schatname = ALLTRIM(THISFORM.txtchatname.VALUE)
         smessagesent = schatname +" says:  " + ALLTRIM(THISFORM.txtmessage.VALUE)
         WITH .winsock1.OBJECT
            .remoteport = 1235
            .remotehost = "127.0.0.1"
            .senddata(smessagesent)
            .remoteport = 1234
            .remotehost = "127.0.0.1"
            .senddata(smessagesent)
         ENDWITH
         .txtmessage.VALUE = ""
      ENDWITH
   ENDPROC

ENDDEFINE

DEFINE CLASS wscontrol AS OLECONTROL
   OLECLASS='MSWinsock.Winsock.1'
   TOP = 228
   LEFT = 24
   HEIGHT = 100
   WIDTH = 100
   NAME = "winsock1"

   PROCEDURE INIT
      THIS.OBJECT.protocol = 1
   ENDPROC

   PROCEDURE dataarrival
      LPARAMETERS bytestotal
      smessage = SPACE(bytestotal)
      THISFORM.winsock1.OBJECT.GETDATA(@smessage)
      THISFORM.edtchat.VALUE = THISFORM.edtchat.VALUE + smessage + CHR(13)
   ENDPROC

ENDDEFINE

Fonte:
[Você precisa estar registrado e conectado para ver este link.]

[hugo]

boa marcos

[Krugzinho]

Olá Sei que este post está muito antigo, porem estou precisando adaptar este chat para utilizalo, porem preciso que ele se conecte ao um host, e não sendo mapeado, digamos que instalado localmente na maquina do cliente.

Pois todos os micros não possuem acesso a mapeamento de unidades então precisava de uma conexão direta por exemplo digitando um IP de servidor e realizando uma conexão, este aplicativo me ajudou bastante porem não é o suficiente.

E como sou iniciante no VFP não sei se isto é possivel fazer nele.

Obrigado !!!