Backup no VFP sem aplicativos 3os. - <<

[hugo]

Fazer backup de dados

Um das mais importantes e mais simples coisas que um usuário de um aplicativo de banco de dados pode fazer é manter um backup atualizado de seu banco de dados do aplicativo.

No entanto, se o usuário não tem algum tipo de software ou hardware que faz um backup automático em um determinado horário que é normal que o desenvolvedor de software implemente de forma fácil de usar o recurso de backup para o aplicativo.

Os dados de execução de backup

Há uma série de coisas a considerar na implementação de um backup de banco de dados para uma aplicação, mas geralmente o desenvolvedor VFP quer simplesmente a capacidade de comprimir arquivos de dados do Visual FoxPro a partir de um diretório em um horário (como todas as noites às 03:00) em um zip que é carimbada com a data e hora. No interesse do cumprimento desses requisitos apresento a ideia de um DataBackup.exe.

DataBackup.exe utiliza o vfpcompression.fll para gerar um arquivo zip de dados contidos em um diretório. O diretório de backup é especificado simplesmente modificando o caminho no arquivo DataBackup.ini. E, com a ajuda do Agendador de Tarefas do Windows (sim, ele está disponível em versões anteriores do Windows), o DataBackup.exe pode facilmente ser executado em uma agenda.

DataBackup.exe foi concebido sem quaisquer elementos GUI, embora haja uma função de progresso que você pode implementar se quiser alguma indicação de progresso quando um backup está em andamento.

Em qualquer caso, DataBackup.exe é projetado para ser facilmente implementado por qualquer aplicação que usa VFP em um diretório que contenha os arquivos de dados.

Nota: os backups (datetime carimbado arquivos zip) são gerados no mesmo diretório onde o DataBackup.exe reside. Além disso, se o DataBackup falhar devido a uma exceção ele irá guardar as informações de mensagem de erro em um arquivo chamado DataBackup.err. Este arquivo pode ser útil na tentativa de diagnosticar problemas quando o DataBackup.exe não está gerando backups como previsto na máquina do usuário.

Melhorias possíveis

Há uma série de coisas que poderia ser feito para melhorar DataBackup.exe, como adicionar um recurso de restauração, que prevê vários diretórios a serem especificados em DataBackup.ini, permitindo subpastas, permitindo que a máscara de arquivo para ser modificado através do DataBackup. ini para fornecer para fazer backup de outros tipos de arquivos, permitem ao usuário especificar onde os backups são criados alem de outras ideias!

Projeto do DataBackup, BAIXE AQUI


Creditos: (Copie e cole em seu navegador)
sweetpotatosoftware.com/spsblog/2008/02/22/VFPDatabaseBackupMadeSimple.aspx


No main.prg voce pode alterar esta linha

Código:

IF INLIST(UPPER(JUSTEXT(m.lcFileName)), "DBF", "CDX", "FPT", "DBC", "DCX", "DCT", "IDX")

e colocar todas as extensoes que desejar fazer o backup

[hugo]

alceu

fiz as alteracoes aqui em casa e interativamente roda perfeito

pelo .exe nao funcionou, nao sei o que vacilei aqui, mais la no
servico eu ja coloquei funcionando no .exe

assim que chegar la eu posto o codigo que coloquei la

valeu

[Julio]

Apesar de ter postado no topico

Barra de progresso muito fina! wow
[Você precisa estar registrado e conectado para ver este link.]

Posto aqui tb minha rotina de backup:

Julio escreveu:

Eu utilizo uma DLL "MOLEZIP.DLL", se não me falhe a memoria é free.

Ai vai meu modelo, a barra é diferente da que tem no form do Alceu, e tambem inferior a beleza da que o Hugo postou.

Utiliza-se de uma classe para fazer a barra de progresso.

Mas em si a rotina faz o backup bem feito.

[Você precisa estar registrado e conectado para ver este link.]


Julio

julio

[hugo]

obrigado julio

[hugo]

alceu

como prometi, copiei a rotina la da empresa e coloquei aqui em casa

interativamente roda perfeito na empresa e aqui em casa

em .exe ( compilado ) funciona perfeito na empresa, aqui em casa
nao funciona o .exe

estou disponibilizando todo o codigo, com as subpastas e etc
para observarem

se puderam me ajudar agradeco muito

alceu, v se roda na sua maquina interativamente e compilado?

me retorna?

to achando que tem algo diferente da maquina la da empresa
pra minha aqui pois la roda o .exe

valeu

anexo codigo

[alceu11]

mas que mensagem ele da qdo esta fazendo backup

pocha aqui nao faz nada. qual o nome do zip que ele cria?

[hugo]

nenhuma, mais posso implementar isto

me da um tempinho

[hugo]

alceu

seguinte, vou te passar passo a passo como estou fazendo aqui

o databackup esta na pasta abaixo:

o:\backup hugo\planeta\backup planeta\databackup\

meu agendador do windows dispara ele as 8.00hs da manha
e repede a cada uma hora ate as 20.00hs

estou utilizando ele pra fazer backup das xmls autorizadas dentro do meu
servidor de backup

em breve vou adicionar mais codigo para fazer todos meus backups

o diretorio a ser backupeado eh o que esta informado dentro do
arquivo databackup.ini, que no meu caso eh o x:\distribuicao\

faco backup de todos xmls que estao dentro desta pasta para
a pasta destino:
o:\backup hugo\planeta\backup planeta\

esta funcionando perfeitamente tanto interativamente quanto compilado

estou te mandando o fonte que estou utilizando sem mudar uma virgula!

fiz algumas adequacoes a partir do original

qualquer coisa so me falar


baixe aqui

obs. vou testar este executavel na minha residencia, desconfio que la o .exe
nao funciona, lembra que algum tempo atras meu f1 (help) vfp nao estava
funcionando? pois eh, desconfio que minha maquina la em casa nao ta muito
benta nao! de qualquer forma eu retorno confirmando!

aqui na empresa ta 110%

lembrando que apesar do modo que estou utilizando, quando o ajax sair
vou usar este esquema de backup

ja ate pensei no form com botao de origem e um de destino, usando no metodo
clique de cada um o =getfile() e =getdir() respectivamente

por enquanto eh isto

valeu professor!

[alceu11]

AGORA FUNCIONOU NAO DAVA POR CAUSA DO ARQUIVO.INI NUNCA ENCONTARIA ESTE PATH X:\DISTR

CODIGO

Código:


#DEFINE CRLF CHR(13) + CHR(10)
LOCAL lcAppPath, lcDataPath, lcZipFileName, llSucceeded, ;
loExc as exception, lcErrorInformation, lcDateTimeString, ;
lcFileName, lnTotalFiles, lnCurrentFile

*m.lcDateTimeString = TTOC(DATETIME(),1)

*!*Definindo nome do arquivo .zip
SET CENTURY on
m.lcdatetimestring="COPIA_" + ALLTRIM(STR(YEAR(DATE())))
IF MONTH(DATE())<10
   m.lcdatetimestring=m.lcdatetimestring+" 0"+ALLTRIM(STR(MONTH(DATE())))
ELSE
   m.lcdatetimestring=m.lcdatetimestring+" "+ALLTRIM(STR(MONTH(DATE())))
ENDIF
IF DAY(DATE())<10
   m.lcdatetimestring=m.lcdatetimestring+" 0"+ALLTRIM(STR(DAY(DATE())))
ELSE
   m.lcdatetimestring=m.lcdatetimestring+" "+ALLTRIM(STR(DAY(DATE())))
ENDIF
IF HOUR(DATETIME())<10
   m.lcdatetimestring=m.lcdatetimestring+" 0"+ALLTRIM(STR(HOUR(DATETIME())))
ELSE
   m.lcdatetimestring=m.lcdatetimestring+" "+ALLTRIM(STR(HOUR(DATETIME())))
ENDIF
IF minute(DATETIME())<10
   m.lcdatetimestring=m.lcdatetimestring+"0"+ALLTRIM(STR(MINUTE(DATETIME())))+"hs"
ELSE
   m.lcdatetimestring=m.lcdatetimestring+ALLTRIM(STR(MINUTE(DATETIME())))+"hs"
ENDIF

*m.lcAppPath = "X:\distribuicao\organizada"

WAIT WINDOW AT 10,49 'ESCOLHA O DIRETORIO A ONDI VAI GRAVAR O BACKUP' NOWAIT
m.lcAppPath =GETDIR() && "c:\UTIL\DATABACKUP_2i3" && *!*Definindo pasta onde vai gravar o .zip


SET SAFETY OFF
SET DEFAULT TO (m.lcAppPath)
SET PATH TO ADDBS(JUSTPATH(SYS(16,0)))
IF FILE("DataBackup.ini")
*   m.lcDataPath = FILETOSTR("DataBackup.ini") && *!* Backup sera feito da pasta informada neste arquivo
WAIT WINDOW AT 10,49 'ESCOLHA O DIRETORIO A ONDI ESTAO OS ARQUIVOS' NOWAIT
m.lcDataPath =GETDIR() && "c:\UTIL\DATABACKUP_2i3"
*   m.lcDataPath = FILETOSTR(ALLTRIM(m.lcDataPath))
   IF DIRECTORY(m.lcDataPath)
       WAIT WINDOW 'Encontrei o diretorio OS ARQUIVOS PARA BACKUP' NOWAIT 
      TRY
         m.lcDataPath = ADDBS(m.lcDataPath)
         IF UserHasExclusiveUse(m.lcDataPath) && Become reasonably sure that files can be read
            SET LIBRARY TO LOCFILE("vfpcompression.fll")
            m.lcZipFileName = m.lcAppPath + m.lcdatetimestring + ".zip"
            WAIT WINDOW m.lczipfilename NOWAIT
            m.llSucceeded = ZipOpen(m.lcZipFileName, m.lcAppPath, .T.)
            IF m.llSucceeded
               m.lnTotalFiles = GetFileCount(m.lcDataPath)
               m.lnCurrentFile = 0
               *!* Backup Files
               WAIT WINDOW "Backup Iniciado" nowait
               m.lcFileName = SYS(2000, m.lcDataPath + "*.*")
               DO WHILE !EMPTY(m.lcFileName)
               
   IF INLIST(UPPER(JUSTEXT(m.lcFileName)), "DBF", "XML", "PRG", "CDX", "FPT", "DBC", "DCX", "DCT", "IDX")
*                  IF INLIST(UPPER(JUSTEXT(m.lcFileName)), "XML") && *!* Estou fazendo backup so de arquivos xml
                     m.lnCurrentFile = m.lnCurrentFile + 1
                     m.llSucceeded = (ZipFile(m.lcDataPath + m.lcFileName, .T.) and m.llSucceeded)
                     Progress(m.lnTotalFiles, m.lnCurrentFile, m.lcFileName)
                  ENDIF
                  m.lcFileName = SYS(2000, m.lcDataPath + "*.*", 1)
               ENDDO
               m.llSucceeded = (ZipClose() and m.llSucceeded)
               WAIT WINDOW "Backup concluido com sucesso" TIMEOUT 0.58
            ENDIF
            SET LIBRARY TO
            *DELETE FILE m.lcdatapath+"*.xml"
         ENDIF
      CATCH TO m.loExc
         m.llSucceeded = .F.
         m.lcErrorInformation = "Line# " + TRANSFORM(m.loExc.LineNo) + CRLF
         m.lcErrorInformation = m.lcErrorInformation + "Error Message '" + m.loExc.Message + "'" + CRLF
         m.lcErrorInformation = m.lcErrorInformation + "Line Contents '" + m.loExc.LineContents + "'" + CRLF
         m.lcErrorInformation = m.lcErrorInformation + "Procedure " + m.loExc.Procedure + CRLF
         =STRTOFILE(m.lcErrorInformation, m.lcAppPath + "DataBackup.err", 1)
      ENDTRY
      
      ELSE && 2 IF
         WAIT WINDOW 'nao encontrei o diretorio' TIMEOUT 1
   ENDIF
   WAIT CLEAR
ENDIF

*******************************
FUNCTION Progress(tnTotalFiles, tnCurrentFile, tcFileName)
*******************************
   LOCAL lnProgressPercent
   m.lnProgressPercent = Round(m.tnCurrentFile/m.tnTotalFiles,0)
   *!* hook progress indication in here
ENDFUNC

*******************************
FUNCTION GetFileCount(tcDataPath)
*******************************
   LOCAL lnTotalFiles, lcFileName
   m.lnTotalFiles = 0
   m.lcFileName = SYS(2000, m.tcDataPath + "*.*")
   DO WHILE !EMPTY(m.lcFileName)
      IF INLIST(UPPER(JUSTEXT(m.lcFileName)), "XML") && *!* Estou fazendo backup so de arquivos xml
         m.lnTotalFiles = m.lnTotalFiles + 1
      ENDIF
      m.lcFileName = SYS(2000, m.tcDataPath + "*.*", 1)
   ENDDO
   RETURN m.lnTotalFiles
ENDFUNC

*******************************
FUNCTION UserHasExclusiveUse(tcDataPath)
*******************************
   LOCAL lcFileName, lnHandle, llReturn
   m.llReturn = .T.
   m.lcFileName = SYS(2000, m.tcDataPath + "*.*")
   DO WHILE !EMPTY(m.lcFileName)
      IF INLIST(UPPER(JUSTEXT(m.lcFileName)), "XML") && *!* Estou fazendo backup so de arquivos xml
         m.lnHandle = FOPEN(m.tcDataPath + m.lcFileName)
         IF m.lnHandle > -1
            =FCLOSE(m.lnHandle)
         ELSE
            m.llReturn = .F.
            EXIT
         ENDIF
      ENDIF
      m.lcFileName = SYS(2000, m.tcDataPath + "*.*", 1)
   ENDDO
   RETURN m.llReturn
ENDFUNC

*!* Definitions of FLL functions to avoid compiler errors
*******************************
FUNCTION ZipOpen
*******************************
FUNCTION ZipFile
*******************************
FUNCTION ZipClose
*******************************



fiz as mundancas que me agradam,,,cada um tem um jeito.
mas ainda tem a possiblidade de escolher os arquivos.




Por hoje chega,,,,muitas informacoes estao me deixando confuso

falta saber se o velho oeste conseguiu gerar chave de instalacao ? e instalou e deu certo?
link
[Você precisa estar registrado e conectado para ver este link.]

[hugo]

alceu
o .exe rodou certinho ai no teu pc?

valeu

[alceu11]

sim desde que tu edit o arquivo ini......por isto fiz as mudancas sem precisar o arquivo ini........

agora tu pode testar em casa que rodara,,,,,,,,
o seu so fazia arquivos xml da nfe....se tu ppegar a agorao meu , ele pegar dbf tp,,,,,,,,e prg........

ok
Continue utilizando a sua rotina para sua empresa,sem utilizar o codigo que modifiquei
pois ela é especifica para agendamento do windows,sem interferencia do usuario.
pois ela esta automatica.

Pois a minha dependera do usuario selecionar as pastas devidas. para ocorrer o backup!!! Enfirm,,,,,,,,o seu otimo!!, As mundancas que fiz ,seria uma alternativa para os visitantes, que buscam uma alternativa de backup no forum.......
Agradeco sua atencao.........

[hugo]

eh o minimo que poderia fazer ne professor

valeu!

[alceu11]

hugo sobre o backup estava procurando e encontrei este artigo
veja que mensagem Alerta , legal de backup

Código:


alerta=CREATEOBJECT("alerta")
alerta.mensagem("O backup foi realizado com sucesso.")

DEFINE CLASS alerta AS form
        Height = 120
        Width = 375
        ShowWindow = 2
        BorderStyle = 0
        Caption = ""
        TitleBar = 0
        AlwaysOnTop = .T.
        BackColor = RGB(14,173,241)
        Name = "alerta"

        ADD OBJECT edtmensagem AS editbox WITH ;
                FontSize = 20, ;
                Alignment = 2, ;
                BackStyle = 0, ;
                BorderStyle = 0, ;
                Height = 103, ;
                Left = 2, ;
                ScrollBars = 0, ;
                Top = 3, ;
                Width = 370, ;
                IntegralHeight = .T., ;
                Name = "edtmensagem"


        PROCEDURE visualizar
                PARAMETERS m.lnAção as Integer
                LOCAL m.lnInicio as Integer, m.lnFim as Integer, m.lnStep as Integer
                m.lnInicio=IIF(m.lnAção=1,10,255)
                m.lnFim=IIF(m.lnAção=1,255,0)
                m.lnStep=IIF(m.lnAção=1,10,-10)
                FOR m.loop1=m.lnInicio TO m.lnFim STEP m.lnStep
                        INKEY(.01,"H")
                        _Sol_SetLayeredWindowAttributes(THISFORM.hWnd, 0, m.loop1, 2)
                ENDFOR
        ENDPROC


        PROCEDURE mensagem
                PARAMETERS m.lcmensagem
                thisform.edtmensagem.Value=m.lcmensagem
                thisform.Visible=.t.
                _Sol_SetLayeredWindowAttributes(THISFORM.hWnd, 0, 10, 2)
                thisform.visualizar(1)
                INKEY(2)
                thisform.visualizar(0)
                _Sol_SetLayeredWindowAttributes(THISFORM.hWnd, 0, 0, 2)
                thisform.Visible=.f.
        ENDPROC


        PROCEDURE Init
                zoom window alerta max
                m.lnHeight=this.Height
                m.lnWitdh=this.Width
                zoom window alerta normal
                this.left=m.lnWitdh-375-10
                this.top=m.lnHeight-120+20
                DECLARE SetWindowLong In Win32Api AS _Sol_SetWindowLong Integer, Integer, Integer
                DECLARE SetLayeredWindowAttributes In Win32Api AS _Sol_SetLayeredWindowAttributes Integer, String, Integer, Integer
                _Sol_SetWindowLong(THISFORM.hWnd, -20, 0x00080000)
                _Sol_SetLayeredWindowAttributes(THISFORM.hWnd, 0, 0, 2)
        ENDPROC


ENDDEFINE


a fonte Fabiano Costa
link
[Você precisa estar registrado e conectado para ver este link.]

[hugo]

muito bom alceu

obrigado por compartilhar

ta reputado

obs, quero ver isto depois, deve ser bem maneiro ne?

[alceu11]

e que o backup seu nao da mensagem , mais acho que nem pode ter?
Mais se tiver!!!
mais e so um alerta para avisar os usuarios , eu gostei da aparencia dela.