Dados do HD, Processador, MAC Adress, etc... <<<

[Marcos Guedes]

Relembrando a primeira mensagem :

Código:

CREATE CURSOR mydisks (driveletter c(1),serialnumber c(50),model c(50),deviceid c(50),volumename c(50),volumeserialnumber c(20))

wmiservices = GETOBJECT("winmgmts:{impersonationLevel=Impersonate}!//.")
wmidiskdrives = wmiservices.execquery("SELECT Model,DeviceID FROM Win32_DiskDrive")

FOR EACH wmidiskdrive IN wmidiskdrives
   lcdeviceid = TRIM(STRTRAN(wmidiskdrive.deviceid,'',''))
   wmidiskpartitions = wmiservices.execquery(;
      'ASSOCIATORS OF {Win32_DiskDrive.DeviceID="' +;
      m.lcdeviceid + '"} WHERE '+ ;
      'AssocClass = Win32_DiskDriveToDiskPartition')

   FOR EACH wmidiskpartition IN wmidiskpartitions
      wmilogicaldisks = wmiservices.execquery( ;
         'ASSOCIATORS OF {Win32_DiskPartition.DeviceID="'+;
         wmidiskpartition.deviceid + '"} WHERE '+;
         'AssocClass = Win32_LogicalDiskToPartition')

      FOR EACH wmilogicaldisk IN wmilogicaldisks
         wmidiskvolumes = wmiservices.execquery(;
            "Select deviceID,VolumeName,VolumeSerialNumber from Win32_LogicalDisk"+;
            " where deviceID = '" + wmilogicaldisk.deviceid + "'" )
         FOR EACH ovolume IN wmidiskvolumes
            lcvolumename = ovolume.volumename
            lcvolumeserialnumber = ovolume.volumeserialnumber
            EXIT
         ENDFOR

         wmidisks = wmiservices.execquery(;
            'SELECT * FROM Win32_PhysicalMedia where Tag="'+m.lcdeviceid+'"')
         FOR EACH wmidisk IN wmidisks
            INSERT INTO mydisks ;
               (driveletter,serialnumber,model,deviceid,volumename,volumeserialnumber) ;
               VALUES ;
               (wmilogicaldisk.deviceid,;
               wmidisk.serialnumber,;
               wmidiskdrive.model,;
               wmidiskdrive.deviceid,;
               m.lcvolumename,;
               m.lcvolumeserialnumber)
         ENDFOR
      ENDFOR
   ENDFOR
ENDFOR
BROWSE

Fonte: (Copie e cole no seu navegador)
windows-tech.info/9/250207c8b3d25d4a.php

[hugo]

leo, providencie pra voce um avatar, usuarios sem avatar estao recebendo
gratuitamente avatar nao muito desejaveis, tipo, mulher invisivel, mulher maravilha e por ai vai

hauahauahaauaha


seguinte


vou te dar uma opcao
em um pc instale o virtualbox
tendo ele bem configurado instale o sistema operacional que quiser
depois ditos instale nele o programa que quizer, validanto e tudo mais

depois, desligue a maquina virtual, copie o arquivo vdi ou vmdk para
uma maquina de backup ou um dvd/cd

va utilizando seu sistema a vontade, se algum dia der pau basta pegar
o arquivo inicial ( vdi, vmdk ) e coloca-lo como hd em qualquer outra
maquina que queira, independente de modelo e pronto

ta la rodando como no dia do backup

claro que voce devera fazer backups dos seus dados proprietarios
para atualizar sua maquina virtual reserva no caso de ter que subir
este teu "stand-by"

agora, se tua pergunta ja é do tipo

tenho um micro com o programa x

quero copias as especificacoes dele pra outra pra poder
piratear um software, ai vou te dizer o seguinte.....
leia as normas do forum, neste forum eh proibido qualquer
conteudo que possa incentivar a pratica de quebra dos direitos
intelecto/autorais

de qualquer forma, se prestar bem atencao na mensagem......
pra quem sabe ler um pingo eh letra!

v se nao some

[Tales Ruan]

Código:

*!* Let's get the CPU ID
LOCAL lcComputerName, loWMI, lowmiWin32Objects, lowmiWin32Object
lcComputerName = GETWORDNUM(SYS(0),1)
loWMI = GETOBJECT("WinMgmts://" + lcComputerName)
lowmiWin32Objects = loWMI.InstancesOf("Win32_Processor")
FOR EACH lowmiWin32Object IN lowmiWin32Objects
    WITH lowmiWin32Object
        ? "ProcessorId: " + TRANSFORM(.ProcessorId)
    ENDWITH
ENDFOR

?
?

*!* Let's get the MAC Address(es)
LOCAL lcComputerName, loWMIService, loItems, loItem, lcMACAddress
lcComputerName = "."
loWMIService = GETOBJECT("winmgmts:\" + lcComputerName + "\root\cimv2")
loItems = loWMIService.ExecQuery("Select * from Win32_NetworkAdapter",,48)
FOR EACH loItem IN loItems
    lcMACAddress = loItem.MACAddress
    IF !ISNULL(lcMACAddress)
        ? "MAC Address: " + loItem.MACAddress
        ?
    ENDIF
ENDFOR

?
?
*!* Let's get the Volume Serial Number(s)
LOCAL lcComputerName, loWMIService, loItems, loItem, lcVolumeSerial
lcComputerName = "."
loWMIService = GETOBJECT("winmgmts:\" + lcComputerName + "\root\cimv2")
loItems = loWMIService.ExecQuery("Select * from Win32_LogicalDisk")
FOR EACH loItem IN loItems
    lcVolumeSerial = loItem.VolumeSerialNumber
    IF !ISNULL(lcVolumeSerial)
        ? "Name: " + loItem.NAME
        ? "Volume Serial Number: " + loItem.VolumeSerialNumber
        ?
    ENDIF
ENDFOR

Pessoal, testei este código que O Marcos colocou no segundo Post e não funcionou no meu computador, um eeePc 904 com Windows Xp. Acusava o seguinte erro em algumas linhas com a função GETOBJECT():

OLE error code 0x800401ea: Moniker não pode abrir arquivo.

Fiz uns ajustes e fiz o código funcionar. Abaixo, o mesmo corrigido, pra quem tiver interesse. Pra mim funcionou:

Código:

clear
*!* Let's get the CPU ID
LOCAL lcComputerName, loWMI, lowmiWin32Objects, lowmiWin32Object
lcComputerName = GETWORDNUM(SYS(0),1)
loWMI = GETOBJECT("WinMgmts://" + lcComputerName)
lowmiWin32Objects = loWMI.InstancesOf("Win32_Processor")
FOR EACH lowmiWin32Object IN lowmiWin32Objects
    WITH lowmiWin32Object
        ? "ProcessorId: " + TRANSFORM(.ProcessorId)
    ENDWITH
ENDFOR

?
?

*!* Let's get the MAC Address(es)
LOCAL lcComputerName, loWMIService, loItems, loItem, lcMACAddress
lcComputerName = "."
loWMIService = GETOBJECT("winmgmts://" + lcComputerName + "/root/cimv2")
loItems = loWMIService.ExecQuery("Select * from Win32_NetworkAdapter",,48)
FOR EACH loItem IN loItems
    lcMACAddress = loItem.MACAddress
    IF !ISNULL(lcMACAddress)
        ? "MAC Address: " + loItem.MACAddress
        ?
    ENDIF
ENDFOR

?
?
*!* Let's get the Volume Serial Number(s)
LOCAL lcComputerName, loWMIService, loItems, loItem, lcVolumeSerial
lcComputerName = "."
loWMIService = GETOBJECT("winmgmts://" + lcComputerName + "/root/cimv2")
loItems = loWMIService.ExecQuery("Select * from Win32_LogicalDisk")
FOR EACH loItem IN loItems
    lcVolumeSerial = loItem.VolumeSerialNumber
    IF !ISNULL(lcVolumeSerial)
        ? "Name: " + loItem.NAME
        ? "Volume Serial Number: " + loItem.VolumeSerialNumber
        ?
    ENDIF
ENDFOR

Alguém mais teve algum problema do tipo?

[Marcos Guedes]

Reputado, Tales!
Quem sabe faz ao vivo.
hehe

[hugo]

reputado cara