Dados do HD, Processador, MAC Adress, etc... <<<

[Marcos Guedes]

Código:

CREATE CURSOR mydisks (driveletter c(1),serialnumber c(50),model c(50),deviceid c(50),volumename c(50),volumeserialnumber c(20))

wmiservices = GETOBJECT("winmgmts:{impersonationLevel=Impersonate}!//.")
wmidiskdrives = wmiservices.execquery("SELECT Model,DeviceID FROM Win32_DiskDrive")

FOR EACH wmidiskdrive IN wmidiskdrives
   lcdeviceid = TRIM(STRTRAN(wmidiskdrive.deviceid,'',''))
   wmidiskpartitions = wmiservices.execquery(;
      'ASSOCIATORS OF {Win32_DiskDrive.DeviceID="' +;
      m.lcdeviceid + '"} WHERE '+ ;
      'AssocClass = Win32_DiskDriveToDiskPartition')

   FOR EACH wmidiskpartition IN wmidiskpartitions
      wmilogicaldisks = wmiservices.execquery( ;
         'ASSOCIATORS OF {Win32_DiskPartition.DeviceID="'+;
         wmidiskpartition.deviceid + '"} WHERE '+;
         'AssocClass = Win32_LogicalDiskToPartition')

      FOR EACH wmilogicaldisk IN wmilogicaldisks
         wmidiskvolumes = wmiservices.execquery(;
            "Select deviceID,VolumeName,VolumeSerialNumber from Win32_LogicalDisk"+;
            " where deviceID = '" + wmilogicaldisk.deviceid + "'" )
         FOR EACH ovolume IN wmidiskvolumes
            lcvolumename = ovolume.volumename
            lcvolumeserialnumber = ovolume.volumeserialnumber
            EXIT
         ENDFOR

         wmidisks = wmiservices.execquery(;
            'SELECT * FROM Win32_PhysicalMedia where Tag="'+m.lcdeviceid+'"')
         FOR EACH wmidisk IN wmidisks
            INSERT INTO mydisks ;
               (driveletter,serialnumber,model,deviceid,volumename,volumeserialnumber) ;
               VALUES ;
               (wmilogicaldisk.deviceid,;
               wmidisk.serialnumber,;
               wmidiskdrive.model,;
               wmidiskdrive.deviceid,;
               m.lcvolumename,;
               m.lcvolumeserialnumber)
         ENDFOR
      ENDFOR
   ENDFOR
ENDFOR
BROWSE

Fonte: (Copie e cole no seu navegador)
windows-tech.info/9/250207c8b3d25d4a.php

[Marcos Guedes]

Código:

*!* Let's get the CPU ID
LOCAL lcComputerName, loWMI, lowmiWin32Objects, lowmiWin32Object
lcComputerName = GETWORDNUM(SYS(0),1)
loWMI = GETOBJECT("WinMgmts://" + lcComputerName)
lowmiWin32Objects = loWMI.InstancesOf("Win32_Processor")
FOR EACH lowmiWin32Object IN lowmiWin32Objects
    WITH lowmiWin32Object
        ? "ProcessorId: " + TRANSFORM(.ProcessorId)
    ENDWITH
ENDFOR

?
?

*!* Let's get the MAC Address(es)
LOCAL lcComputerName, loWMIService, loItems, loItem, lcMACAddress
lcComputerName = "."
loWMIService = GETOBJECT("winmgmts:\" + lcComputerName + "\root\cimv2")
loItems = loWMIService.ExecQuery("Select * from Win32_NetworkAdapter",,48)
FOR EACH loItem IN loItems
    lcMACAddress = loItem.MACAddress
    IF !ISNULL(lcMACAddress)
        ? "MAC Address: " + loItem.MACAddress
        ?
    ENDIF
ENDFOR

?
?
*!* Let's get the Volume Serial Number(s)
LOCAL lcComputerName, loWMIService, loItems, loItem, lcVolumeSerial
lcComputerName = "."
loWMIService = GETOBJECT("winmgmts:\" + lcComputerName + "\root\cimv2")
loItems = loWMIService.ExecQuery("Select * from Win32_LogicalDisk")
FOR EACH loItem IN loItems
    lcVolumeSerial = loItem.VolumeSerialNumber
    IF !ISNULL(lcVolumeSerial)
        ? "Name: " + loItem.NAME
        ? "Volume Serial Number: " + loItem.VolumeSerialNumber
        ?
    ENDIF
ENDFOR

Código:

?GetVolumeSerial("C")

FUNCTION GetVolumeSerial(tcDrive)
    IF PCOUNT() = 0
        tcDrive = "C:"
    ELSE
        tcDrive = STRTRAN(tcDrive, ":", "") + ":"
    ENDIF
    LOCAL lcName, lcFSName, lnVolumeSerial, ;
        lnFMaxLen, lnFSFlags, ;
        lcVolumeSerial, lnNameLen, lnFSNameLen

    STORE SPACE(255) TO lcName, lcFSName
    STORE 0 TO lnVolumeSerial, lnFMaxLen, lnFSFlags
    STORE 255 TO lnNameLen, lnFSNameLen

    DECLARE GetVolumeInformation IN win32api STRING, STRING @, ;
        INTEGER, INTEGER @, INTEGER @, INTEGER @, STRING @, INTEGER

    =GetVolumeInformation(tcDrive, @lcName, lnNameLen, ;
        @lnVolumeSerial, @lnFMaxLen, @lnFSFlags, @lcFSName, lnFSNameLen)
       
    CLEAR DLLS GetVolumeInformation
   
    IF EMPTY(lnVolumeSerial)
        RETURN ""
    ELSE
        IF lnVolumeSerial < 0
            lnVolumeSerial = 4294967296 + lnVolumeSerial
        ENDIF
        lcVolumeSerial = SUBSTR(TRANSFORM(lnVolumeSerial,"@0"), 3)
        RETURN lcVolumeSerial
    ENDIF
ENDFUNC

?GetMACAddress()

FUNCTION GetMACAddress()
lcFile = ADDBS(SYS(2023)) + "_"+SUBSTR(SYS(2015), 4)  + ".tmp"
lcCommand = "ipconfig /all >" + lcFile
DECLARE INTEGER WinExec IN win32api ;
  STRING command, INTEGER param
=WinExec(SYS(2004) + "FOXRUN.PIF /C " + lcCommand, 0)
CLEAR DLLS WinExec
*!* This next line may not be necessary on all computers...included JIC
=INKEY(1, "H") &&Slow VFP down so windows can make the file first
IF FILE(lcFile)
    lcOutput = FILETOSTR(lcFile)
    ERASE (lcFile)
ELSE
    RETURN "" &&Couldn't create file
ENDIF

lnAt = AT('Physical Address. . . . . . . . . : ', lcOutput)
IF lnAt > 0
    lcMAC = UPPER(STRTRAN(SUBSTR(lcOutput, lnAt + 36 , 17), '-',''))
ENDIF

RETURN lcMAC

Fonte: (Copie e cole em seu navegador)
tek-tips.com/viewthread.cfm?qid=756938

[hugo]

opa marcos

estes codigos poderiam ser usados para verificar se o sistema esta na maquina a que se destina, correto???

[mfelis]

Provavelmente é só você armazenar a serial do HD da Máquina e toda vez que seu sistema iniciar comparar ela,se for igual está na maquina certa. o problema está se o cliente mudar o HD!!!.Então parte para o Processador a Melhor forma é pelo MAC Adress

[hugo]

clonagem de mac adress tambem existe! hehe

marcos
o serial eh do volume do hd ou eh o serial fisico?
de qualquer forma nao adianta pois se o sistema for virtualizado podera
ser copiado

sobre os dados do processador, ele pega o nr do modelo ou pega o serial mesmo?

alguma ideia talvez de pegar o serial da bios?

hd clonado copia serial do volume, mais o cara conseguir
ter o mesmo serial de volume (clonando), + mesmo mac address + mesmo serial de processador ele ate merece uma copia pirata!
hauahauhauahauahauah

valeu

[Marcos Guedes]

Ainda é necessário testar.
Postei logo estes códigos para não perdermos quando precisarmos.


Mas no primeiro exemplo, execute e veja que o curso exibe dois números de série do volume do HD.


Já dá para brincar legal com ele.
Quanto a virtualização, se não me falha a memória, a máquina virtualizada recebe um IP totalmente diferente da máquina principal.

Ex.:
Meu Ubuntu: 192.168.1.10
Meu XP virtual: 10.0.2.15

Apartir daí, é só colocar os neurônios para funcionar.


Combina a maior possibilidades possíveis, e no caso, como o Marcelo falou, havendo uma substituição de driver, certamente deverá haver uma reinstalação.

[hugo]

marcos, mac address nao eh nr de ip, se se enganou ai amigao

exemplo de mac address

00-24-1d-fd-6e-1b

tem como voce clonar um mac address de um adaptador de rede para outra maquina

quanto ao ip do virtual voce pode trabalhar com eles na mesma faixa sem nenhum problema, eh so configurar

[Marcos Guedes]

marcos, mac address nao eh nr de ip, se se enganou ai amigao

exemplo de mac address

00-24-1d-fd-6e-1b

tem como voce clonar um mac address de um adaptador de rede para outra maquina

quanto ao ip do virtual voce pode trabalhar com eles na mesma faixa sem nenhum problema, eh so configurar

Hugão, você não entendeu minha mensagem!
Releia por favor!

Fiz referência ao IP, mesmo.
Vocês citaram a possibilidade de clonagem ou falha/troca de hardware.

Então mostrei outra opção que pode ser avaliada na máquina (em caso de virtualização) que é o IP.

[hugo]

o titulo tem MAC ADDRESS

ta reputado de qualquer jeito

c ja sabe onde vou usar isto ne marcos?

hehehe

[Marcos Guedes]

o titulo tem MAC ADDRESS...

IP foi apenas uma dica, mas não consta no código.

c ja sabe onde vou usar isto ne marcos?

[Leo Marques]

ola pessoal sou novo no forum mais tenho interesse sobre este assunto...
eh realmente viavel? como fazer em uma maquina virtual java?

[hugo]

leo, seja bem vindo

c ja se apresentou pra galera amigao?

abraxxx por enquanto!

[Marcos Guedes]

ola pessoal sou novo no forum mais tenho interesse sobre este assunto...
eh realmente viavel? como fazer em uma maquina virtual java?

Leo, primeiramente, seja bem vindo!

Quanto a sua mensagem, não entendi sua dúvida.
O que seria realmente viável?

Se sua dúvida estiver ligada a Java, favor postar com mais detalhes, abrindo um novo tópico no seguinte link:

- [Você precisa estar registrado e conectado para ver este link.]

Agradecemos sua compreensão e participação.

[Leo Marques]

Hugo & Marcos,


Obrigado pela recepcao!!!

Desculpe, talvez me expressei errado e antecipadamente ao inves de viavel seria, possivel....

Pelo que entendi eh possivel descobrir todas estas informacoes descritas acima de um pc e alterar em uma maquina virtual fazendo um pc se passar por outro(clone).

Para que quando um sistema for rodado conferir se aquele pc realmente eh o "cadastrado" e liberar o acesso

Minha pergunda seria neste sentido... se for isso mesmo que entendi...
Tenho interesse em aprender como fazer.. se nao for desculpa...

Obrigado!!!

[Marcos Guedes]

O tópico mostra como obter alguns dados de alguns dispositivos do PC.
Tendo dúvidas, é só postar no local reservado a sua linguagem de programação desejada.